media-tv/linuxtv-dvb-apps/linuxtv-dvb-apps-1.1.1.20140321-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit toolchain-funcs vcs-snapshot
   7
   8 HOMEPAGE="https://www.linuxtv.org/"
   9 DESCRIPTION="Small utils for DVB to scan, zap, view signal strength"
  10 SRC_URI="https://www.linuxtv.org/hg/dvb-apps/archive/3d43b280298c.tar.bz2 -> ${P}.tar.bz2"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~arm ~ppc ~x86"
  15 IUSE="alevt usb"
  16
  17 RDEPEND="
  18         alevt? (
  19                 !media-video/alevt
  20                 media-libs/libpng:0=
  21                 media-libs/zvbi[v4l]
  22                 sys-libs/zlib
  23                 x11-libs/libX11
  24         )
  25         usb? ( virtual/libusb:0 )
  26 "
  27 DEPEND="${RDEPEND}
  28         dev-lang/perl
  29         virtual/linuxtv-dvb-headers
  30 "
  31 RDEPEND+="
  32         media-tv/dtv-scan-tables
  33 "
  34
  35 PATCHES=(
  36         "${FILESDIR}"/${PN}-1.1.1.20100223-ldflags.patch
  37         "${FILESDIR}"/${PN}-1.1.1.20100223-alevt.patch
  38         "${FILESDIR}"/${PN}-1.1.1.20100223-perl526.patch
  39         "${FILESDIR}"/${PN}-no-ca_set_pid.patch
  40         "${FILESDIR}"/${PN}-glibc-2.31.patch
  41 )
  42
  43 src_prepare() {
  44         default
  45
  46         # do not compile test-progs, incompatible with videodev2.h
  47         sed -i '/-C test/d' Makefile || die
  48
  49         # remove copy of header-files
  50         rm -rv "${S}"/include/ || die
  51 }
  52
  53 src_compile() {
  54         emake V=1 CC=$(tc-getCC) $(usex usb "ttusb_dec_reset=1" "")
  55         use alevt && emake -C util/alevt CC=$(tc-getCC) OPT="${CFLAGS}"
  56 }
  57
  58 src_install() {
  59         emake V=1 prefix="${EPREFIX}/usr" libdir="${EPREFIX}/usr/$(get_libdir)" \
  60                 $(usex usb "ttusb_dec_reset=1" "") \
  61                 DESTDIR="${D}" INSTDIR="${T}" install
  62
  63         if use alevt ; then
  64                 dodir /usr/share/{applications,man/man1}
  65                 emake -C util/alevt DESTDIR="${D}" install
  66         fi
  67
  68         # rename scan to scan-dvb
  69         mv "${ED}"/usr/bin/scan{,-dvb} || die
  70
  71         # install zap-files
  72         local dir=""
  73         for dir in dvb-{s,c,t} atsc ; do
  74                 insinto /usr/share/dvb/zap/${dir}
  75                 doins "${S}"/util/szap/channels-conf/${dir}/*
  76         done
  77
  78         # install remote-key files
  79         insinto /usr/share/dvb/av7110_loadkeys
  80         doins util/av7110_loadkeys/*.rc*
  81
  82         # install Documentation
  83         dodoc README
  84         newdoc util/scan/README README.scan-dvb
  85         newdoc util/szap/README README.zap
  86         newdoc util/av7110_loadkeys/README README.av7110_loadkeys
  87
  88         use usb && newdoc util/ttusb_dec_reset/README README.ttusb_dec_reset
  89 }
  90
  91 pkg_postinst() {
  92         elog "/usr/bin/scan has been installed as scan-dvb."
  93 }