media-tv/kodi/kodi-18.3-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_REQ_USE="libressl?,sqlite,ssl"
   7 LIBDVDCSS_VERSION="1.4.2-Leia-Beta-5"
   8 LIBDVDREAD_VERSION="6.0.0-Leia-Alpha-3"
   9 LIBDVDNAV_VERSION="6.0.0-Leia-Alpha-3"
  10 FFMPEG_VERSION="4.0.3"
  11 CODENAME="Leia"
  12 FFMPEG_KODI_VERSION="18.2"
  13 SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_VERSION}.tar.gz -> libdvdcss-${LIBDVDCSS_VERSION}.tar.gz
  14         https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_VERSION}.tar.gz -> libdvdread-${LIBDVDREAD_VERSION}.tar.gz
  15         https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_VERSION}.tar.gz -> libdvdnav-${LIBDVDNAV_VERSION}.tar.gz
  16         !system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz )"
  17
  18 if [[ ${PV} == *9999 ]] ; then
  19         PYTHON_COMPAT=( python2_7 python3_{6,7} )
  20         EGIT_REPO_URI="https://github.com/xbmc/xbmc.git"
  21         inherit git-r3
  22 else
  23         PYTHON_COMPAT=( python2_7 )
  24         MY_PV=${PV/_p/_r}
  25         MY_PV=${MY_PV/_alpha/a}
  26         MY_PV=${MY_PV/_beta/b}
  27         MY_PV=${MY_PV/_rc/rc}
  28         MY_P="${PN}-${MY_PV}"
  29         SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}-${CODENAME}.tar.gz -> ${MY_P}.tar.gz"
  30         KEYWORDS="~amd64 ~x86"
  31         S=${WORKDIR}/xbmc-${MY_PV}-${CODENAME}
  32 fi
  33
  34 inherit autotools cmake eutils gnome2-utils linux-info pax-utils python-single-r1 xdg-utils
  35
  36 DESCRIPTION="A free and open source media-player and entertainment hub"
  37 HOMEPAGE="https://kodi.tv/ https://kodi.wiki/"
  38
  39 LICENSE="GPL-2+"
  40 SLOT="0"
  41 # use flag is called libusb so that it doesn't fool people in thinking that
  42 # it is _required_ for USB support. Otherwise they'll disable udev and
  43 # that's going to be worse.
  44 IUSE="airplay alsa bluetooth bluray caps cec +css dbus dvd gbm gles lcms libressl libusb lirc mariadb mysql nfs +opengl pulseaudio raspberry-pi samba systemd +system-ffmpeg test +udev udisks upnp upower vaapi vdpau wayland webserver +X +xslt zeroconf"
  45 RESTRICT="!test? ( test )"
  46 REQUIRED_USE="
  47         ${PYTHON_REQUIRED_USE}
  48         || ( gles opengl )
  49         ^^ ( gbm raspberry-pi wayland X )
  50         ?? ( mariadb mysql )
  51         udev? ( !libusb )
  52         udisks? ( dbus )
  53         upower? ( dbus )
  54 "
  55
  56 COMMON_DEPEND="${PYTHON_DEPS}
  57         airplay? (
  58                 >=app-pda/libplist-2.0.0
  59                 net-libs/shairplay
  60         )
  61         alsa? ( >=media-libs/alsa-lib-1.1.4.1 )
  62         bluetooth? ( net-wireless/bluez )
  63         bluray? ( >=media-libs/libbluray-1.0.2 )
  64         caps? ( sys-libs/libcap )
  65         dbus? ( sys-apps/dbus )
  66         dev-db/sqlite
  67         dev-libs/expat
  68         dev-libs/flatbuffers
  69         >=dev-libs/fribidi-0.19.7
  70         cec? ( >=dev-libs/libcec-4.0[raspberry-pi?] )
  71         dev-libs/libpcre[cxx]
  72         >=dev-libs/libinput-1.10.5
  73         >=dev-libs/libxml2-2.9.4
  74         >=dev-libs/lzo-2.04
  75         dev-libs/tinyxml[stl]
  76         $(python_gen_cond_dep 'dev-python/pillow[${PYTHON_MULTI_USEDEP}]')
  77         $(python_gen_cond_dep 'dev-python/pycryptodome[${PYTHON_MULTI_USEDEP}]' 'python3*')
  78         >=dev-libs/libcdio-0.94
  79         >=dev-libs/libfmt-3.0.1
  80         dev-libs/libfstrcmp
  81         gbm? (  media-libs/mesa[gbm] )
  82         gles? (
  83                 !raspberry-pi? ( media-libs/mesa[gles2] )
  84         )
  85         lcms? ( media-libs/lcms:2 )
  86         libusb? ( virtual/libusb:1 )
  87         virtual/ttf-fonts
  88         media-fonts/roboto
  89         >=media-libs/fontconfig-2.12.4
  90         >=media-libs/freetype-2.8
  91         >=media-libs/libass-0.13.4
  92         !raspberry-pi? ( media-libs/mesa[egl,X(+)] )
  93         >=media-libs/taglib-1.11.1
  94         system-ffmpeg? (
  95                 >=media-video/ffmpeg-${FFMPEG_VERSION}:=[encode,postproc]
  96                 libressl? ( media-video/ffmpeg[libressl,-openssl] )
  97                 !libressl? ( media-video/ffmpeg[-libressl,openssl] )
  98         )
  99         mysql? ( dev-db/mysql-connector-c:= )
 100         mariadb? ( dev-db/mariadb-connector-c:= )
 101         >=net-misc/curl-7.56.1[http2]
 102         nfs? ( >=net-fs/libnfs-2.0.0:= )
 103         opengl? ( media-libs/glu )
 104         !libressl? ( >=dev-libs/openssl-1.0.2l:0= )
 105         libressl? ( dev-libs/libressl:0= )
 106         raspberry-pi? (
 107                 || ( media-libs/raspberrypi-userland media-libs/raspberrypi-userland-bin media-libs/mesa[egl,gles2,vc4] )
 108         )
 109         pulseaudio? ( media-sound/pulseaudio )
 110         samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
 111         >=sys-libs/zlib-1.2.11
 112         udev? ( virtual/udev )
 113         vaapi? (
 114                 x11-libs/libva:=
 115                 opengl? ( x11-libs/libva[opengl] )
 116                 system-ffmpeg? ( media-video/ffmpeg[vaapi] )
 117                 vdpau? ( x11-libs/libva[vdpau] )
 118                 wayland? ( x11-libs/libva[wayland] )
 119                 X? ( x11-libs/libva[X] )
 120         )
 121         virtual/libiconv
 122         vdpau? (
 123                 || ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
 124                 system-ffmpeg? ( media-video/ffmpeg[vdpau] )
 125         )
 126         wayland? (
 127                 >=dev-cpp/waylandpp-0.2.3:=
 128                 media-libs/mesa[wayland]
 129                 >=dev-libs/wayland-protocols-1.7
 130         )
 131         webserver? ( >=net-libs/libmicrohttpd-0.9.55[messages(+)] )
 132         X? (
 133                 x11-libs/libX11
 134                 x11-libs/libXrandr
 135                 x11-libs/libXrender
 136                 system-ffmpeg? ( media-video/ffmpeg[X] )
 137         )
 138         x11-libs/libdrm
 139         >=x11-libs/libxkbcommon-0.4.1
 140         xslt? ( dev-libs/libxslt )
 141         zeroconf? ( net-dns/avahi[dbus] )
 142 "
 143 RDEPEND="${COMMON_DEPEND}
 144         lirc? ( app-misc/lirc )
 145         !media-tv/xbmc
 146         udisks? ( sys-fs/udisks:2 )
 147         upower? ( sys-power/upower )
 148 "
 149 DEPEND="${COMMON_DEPEND}
 150         app-arch/bzip2
 151         app-arch/xz-utils
 152         dev-lang/swig
 153         dev-libs/crossguid
 154         dev-libs/rapidjson
 155         dev-util/cmake
 156         dev-util/gperf
 157         media-libs/giflib
 158         >=media-libs/libjpeg-turbo-1.5.1:=
 159         >=media-libs/libpng-1.6.26:0=
 160         test? ( dev-cpp/gtest )
 161         virtual/pkgconfig
 162         virtual/jre
 163         x86? ( dev-lang/nasm )
 164 "
 165
 166 CONFIG_CHECK="~IP_MULTICAST"
 167 ERROR_IP_MULTICAST="
 168 In some cases Kodi needs to access multicast addresses.
 169 Please consider enabling IP_MULTICAST under Networking options.
 170 "
 171
 172 pkg_setup() {
 173         check_extra_config
 174         python-single-r1_pkg_setup
 175 }
 176
 177 src_unpack() {
 178         if [[ ${PV} == *9999 ]] ; then
 179                 if python_is_python3; then
 180                         EGIT_BRANCH="feature_python3"
 181                         ewarn "Using the experimental Python 3 branch!"
 182                         ewarn "See https://kodi.wiki/view/Migration_to_Python_3 for more information."
 183                         ewarn "To use the non-experimental Python 2 version:"
 184                         ewarn "echo '~${CATEGORY}/${P} PYTHON_TARGETS: -* python2_7 PYTHON_SINGLE_TARGET: -* python2_7' >> /etc/portage/package.use"
 185                         ewarn "then re-merge using: emerge -a =${CATEGORY}/${PF}"
 186                 fi
 187                 git-r3_src_unpack
 188         else
 189                 default
 190         fi
 191 }
 192
 193 src_prepare() {
 194         cmake_src_prepare
 195
 196         # avoid long delays when powerkit isn't running #348580
 197         sed -i \
 198                 -e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
 199                 xbmc/platform/linux/*.cpp || die
 200
 201         # Prepare tools and libs witch are configured with autotools during compile time
 202         AUTOTOOLS_DIRS=(
 203                 "${S}"/lib/cpluff
 204                 "${S}"/tools/depends/native/TexturePacker/src
 205                 "${S}"/tools/depends/native/JsonSchemaBuilder/src
 206         )
 207
 208         local d
 209         for d in "${AUTOTOOLS_DIRS[@]}" ; do
 210                 pushd ${d} >/dev/null || die
 211                 AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
 212                 popd >/dev/null || die
 213         done
 214         elibtoolize
 215
 216         # Prevent autoreconf rerun
 217         sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
 218                 "${S}"/cmake/modules/FindCpluff.cmake \
 219                 "${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
 220                 "${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \
 221                 || die
 222 }
 223
 224 src_configure() {
 225         local mycmakeargs=(
 226                 -Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
 227                 -DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
 228                 -DENABLE_ALSA=$(usex alsa)
 229                 -DENABLE_AIRTUNES=$(usex airplay)
 230                 -DENABLE_AVAHI=$(usex zeroconf)
 231                 -DENABLE_BLUETOOTH=$(usex bluetooth)
 232                 -DENABLE_BLURAY=$(usex bluray)
 233                 -DENABLE_CCACHE=OFF
 234                 -DENABLE_CEC=$(usex cec)
 235                 -DENABLE_DBUS=$(usex dbus)
 236                 -DENABLE_DVDCSS=$(usex css)
 237                 -DENABLE_INTERNAL_CROSSGUID=OFF
 238                 -DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
 239                 -DENABLE_INTERNAL_FSTRCMP=OFF
 240                 -DENABLE_CAP=$(usex caps)
 241                 -DENABLE_LCMS2=$(usex lcms)
 242                 -DENABLE_LIRCCLIENT=$(usex lirc)
 243                 -DENABLE_MARIADBCLIENT=$(usex mariadb)
 244                 -DENABLE_MYSQLCLIENT=$(usex mysql)
 245                 -DENABLE_MICROHTTPD=$(usex webserver)
 246                 -DENABLE_MYSQLCLIENT=$(usex mysql)
 247                 -DENABLE_NFS=$(usex nfs)
 248                 -DENABLE_OPENGLES=$(usex gles)
 249                 -DENABLE_OPENGL=$(usex opengl)
 250                 -DENABLE_OPTICAL=$(usex dvd)
 251                 -DENABLE_PLIST=$(usex airplay)
 252                 -DENABLE_PULSEAUDIO=$(usex pulseaudio)
 253                 -DENABLE_SMBCLIENT=$(usex samba)
 254                 -DENABLE_UDEV=$(usex udev)
 255                 -DENABLE_UPNP=$(usex upnp)
 256                 -DENABLE_VAAPI=$(usex vaapi)
 257                 -DENABLE_VDPAU=$(usex vdpau)
 258                 -DENABLE_XSLT=$(usex xslt)
 259                 -Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_VERSION}.tar.gz"
 260                 -Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_VERSION}.tar.gz"
 261                 -Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_VERSION}.tar.gz"
 262         )
 263
 264         use libusb && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
 265
 266         if use system-ffmpeg; then
 267                 mycmakeargs+=( -DWITH_FFMPEG="yes" )
 268         else
 269                 mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz" )
 270         fi
 271
 272         if use gbm; then
 273                 mycmakeargs+=(
 274                         -DCORE_PLATFORM_NAME="gbm"
 275                         -DGBM_RENDER_SYSTEM="$(usex opengl gl gles)"
 276                 )
 277         fi
 278
 279         if use wayland; then
 280                 mycmakeargs+=(
 281                         -DCORE_PLATFORM_NAME="wayland"
 282                         -DWAYLAND_RENDER_SYSTEM="$(usex opengl gl gles)"
 283                 )
 284         fi
 285
 286         if use raspberry-pi; then
 287                 mycmakeargs+=( -DCORE_PLATFORM_NAME="rbpi" )
 288         fi
 289
 290         if use X; then
 291                 mycmakeargs+=( -DCORE_PLATFORM_NAME="x11" )
 292         fi
 293
 294         cmake_src_configure
 295 }
 296
 297 src_compile() {
 298         cmake_src_compile all
 299 }
 300
 301 src_test() {
 302         cmake_build check
 303 }
 304
 305 src_install() {
 306         cmake_src_install
 307
 308         pax-mark Em "${ED}"/usr/$(get_libdir)/${PN}/${PN}.bin
 309
 310         newicon media/icon48x48.png kodi.png
 311
 312         rm "${ED}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
 313         dosym ../../../../fonts/roboto/Roboto-Thin.ttf \
 314                 usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
 315
 316         python_domodule tools/EventClients/lib/python/xbmcclient.py
 317         python_newscript "tools/EventClients/Clients/KodiSend/kodi-send.py" kodi-send
 318 }
 319
 320 pkg_postinst() {
 321         gnome2_icon_cache_update
 322         xdg_desktop_database_update
 323 }
 324
 325 pkg_postrm() {
 326         gnome2_icon_cache_update
 327         xdg_desktop_database_update
 328 }