media-tv/kodi/kodi-17.6.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 # Does not work with py3 here
   7 PYTHON_COMPAT=( python2_7 )
   8 PYTHON_REQ_USE="sqlite"
   9
  10 inherit autotools cmake-utils eutils linux-info pax-utils python-single-r1 versionator
  11
  12 LIBDVDCSS_COMMIT="2f12236bc1c92f73c21e973363f79eb300de603f"
  13 LIBDVDREAD_COMMIT="17d99db97e7b8f23077b342369d3c22a6250affd"
  14 LIBDVDNAV_COMMIT="43b5f81f5fe30bceae3b7cecf2b0ca57fc930dac"
  15 FFMPEG_VERSION="3.1.11"
  16 FFMPEG_KODI_VERSION="17.5"
  17 CODENAME="Krypton"
  18 SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_COMMIT}.tar.gz -> libdvdcss-${LIBDVDCSS_COMMIT}.tar.gz
  19         https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_COMMIT}.tar.gz -> libdvdread-${LIBDVDREAD_COMMIT}.tar.gz
  20         https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_COMMIT}.tar.gz -> libdvdnav-${LIBDVDNAV_COMMIT}.tar.gz
  21         !system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz )"
  22
  23 DESCRIPTION="A free and open source media-player and entertainment hub"
  24 HOMEPAGE="https://kodi.tv/ https://kodi.wiki/"
  25
  26 LICENSE="GPL-2"
  27 SLOT="0"
  28 # use flag is called libusb so that it doesn't fool people in thinking that
  29 # it is _required_ for USB support. Otherwise they'll disable udev and
  30 # that's going to be worse.
  31 IUSE="airplay alsa bluetooth bluray caps cec +css dbus debug dvd gles lcms libressl libusb lirc mysql nfs nonfree +opengl pulseaudio samba sftp systemd +system-ffmpeg test +udev udisks upnp upower vaapi vdpau webserver +X +xslt zeroconf"
  32 REQUIRED_USE="
  33         ${PYTHON_REQUIRED_USE}
  34         || ( gles opengl )
  35         gles? ( X )
  36         opengl? ( X )
  37         udev? ( !libusb )
  38         udisks? ( dbus )
  39         upower? ( dbus )
  40 "
  41
  42 COMMON_DEPEND="${PYTHON_DEPS}
  43         airplay? (
  44                 app-pda/libplist
  45                 net-libs/shairplay
  46         )
  47         alsa? ( media-libs/alsa-lib )
  48         bluetooth? ( net-wireless/bluez )
  49         bluray? ( >=media-libs/libbluray-0.7.0 )
  50         caps? ( sys-libs/libcap )
  51         dbus? ( sys-apps/dbus )
  52         dev-db/sqlite
  53         dev-libs/expat
  54         dev-libs/fribidi
  55         cec? ( >=dev-libs/libcec-4.0 )
  56         dev-libs/libpcre[cxx]
  57         dev-libs/libxml2
  58         >=dev-libs/lzo-2.04
  59         dev-libs/tinyxml[stl]
  60         >=dev-libs/yajl-2
  61         dev-python/pillow[${PYTHON_USEDEP}]
  62         dev-libs/libcdio
  63         gles? ( media-libs/mesa[gles2] )
  64         lcms? ( media-libs/lcms:2 )
  65         libusb? ( virtual/libusb:1 )
  66         media-fonts/corefonts
  67         >=media-fonts/noto-20160531
  68         media-fonts/roboto
  69         media-libs/fontconfig
  70         media-libs/freetype
  71         >=media-libs/libass-0.13.4
  72         media-libs/mesa[egl]
  73         >=media-libs/taglib-1.11.1
  74         system-ffmpeg? (
  75                 >=media-video/ffmpeg-${FFMPEG_VERSION}:=[encode,openssl,postproc]
  76                 <media-video/ffmpeg-3.4
  77         )
  78         mysql? ( virtual/mysql )
  79         >=net-misc/curl-7.51.0
  80         nfs? ( net-fs/libnfs:= )
  81         opengl? ( media-libs/glu )
  82         !libressl? ( >=dev-libs/openssl-1.0.2j:0= )
  83         libressl? ( dev-libs/libressl:0= )
  84         pulseaudio? ( media-sound/pulseaudio )
  85         samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
  86         sftp? ( net-libs/libssh[sftp] )
  87         sys-libs/zlib
  88         udev? ( virtual/udev )
  89         vaapi? ( x11-libs/libva[opengl] )
  90         vdpau? (
  91                 || ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
  92                 system-ffmpeg? ( media-video/ffmpeg[vdpau] )
  93         )
  94         webserver? ( >=net-libs/libmicrohttpd-0.9.50[messages] )
  95         X? (
  96                 x11-libs/libdrm
  97                 x11-libs/libX11
  98                 x11-libs/libXrandr
  99                 x11-libs/libXrender
 100         )
 101         xslt? ( dev-libs/libxslt )
 102         zeroconf? ( net-dns/avahi[dbus] )
 103 "
 104 RDEPEND="${COMMON_DEPEND}
 105         lirc? (
 106                 || ( app-misc/lirc app-misc/inputlircd )
 107         )
 108         !media-tv/xbmc
 109         udisks? ( sys-fs/udisks:0 )
 110         upower? (
 111                 systemd? ( sys-power/upower )
 112                 !systemd? (
 113                         || ( sys-power/upower-pm-utils sys-power/upower )
 114                 )
 115         )
 116 "
 117 DEPEND="${COMMON_DEPEND}
 118         app-arch/bzip2
 119         app-arch/unzip
 120         app-arch/xz-utils
 121         app-arch/zip
 122         dev-lang/swig
 123         dev-libs/crossguid
 124         dev-util/cmake
 125         dev-util/gperf
 126         media-libs/giflib
 127         >=media-libs/libjpeg-turbo-1.5.1:=
 128         >=media-libs/libpng-1.6.26:0=
 129         test? ( dev-cpp/gtest )
 130         virtual/pkgconfig
 131         x86? ( dev-lang/nasm )
 132 "
 133 case ${PV} in
 134 9999)
 135         EGIT_REPO_URI="https://github.com/xbmc/xbmc.git"
 136         inherit git-r3
 137         # Force java for latest git version to avoid having to hand maintain the
 138         # generated addons package.  #488118
 139         DEPEND+="
 140                 virtual/jre
 141                 "
 142         ;;
 143 *)
 144         MY_PV=${PV/_p/_r}
 145         MY_PV=${MY_PV/_alpha/a}
 146         MY_PV=${MY_PV/_beta/b}
 147         MY_PV=${MY_PV/_rc/rc}
 148         MY_P="${PN}-${MY_PV}"
 149         SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}-${CODENAME}.tar.gz -> ${MY_P}.tar.gz
 150                  !java? ( https://github.com/candrews/gentoo-kodi/raw/master/${MY_P}-generated-addons.tar.xz )"
 151         KEYWORDS="~amd64 ~x86"
 152         IUSE+=" java"
 153         DEPEND+="
 154                 java? ( virtual/jre )
 155                 "
 156
 157         S=${WORKDIR}/xbmc-${MY_PV}-${CODENAME}
 158         ;;
 159 esac
 160
 161 CONFIG_CHECK="~IP_MULTICAST"
 162 ERROR_IP_MULTICAST="
 163 In some cases Kodi needs to access multicast addresses.
 164 Please consider enabling IP_MULTICAST under Networking options.
 165 "
 166
 167 CMAKE_USE_DIR=${S}/project/cmake/
 168
 169 pkg_setup() {
 170         check_extra_config
 171         python-single-r1_pkg_setup
 172 }
 173
 174 src_prepare() {
 175         if in_iuse java && use !java; then
 176                 eapply "${FILESDIR}"/${PN}-cmake-no-java.patch
 177         fi
 178         cmake-utils_src_prepare
 179
 180         # avoid long delays when powerkit isn't running #348580
 181         sed -i \
 182                 -e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
 183                 xbmc/linux/*.cpp || die
 184
 185         # Prepare tools and libs witch are configured with autotools during compile time
 186         AUTOTOOLS_DIRS=(
 187                 "${S}"/lib/cpluff
 188                 "${S}"/tools/depends/native/TexturePacker/src
 189                 "${S}"/tools/depends/native/JsonSchemaBuilder/src
 190         )
 191
 192         local d
 193         for d in "${AUTOTOOLS_DIRS[@]}" ; do
 194                 pushd ${d} >/dev/null || die
 195                 AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
 196                 popd >/dev/null || die
 197         done
 198         elibtoolize
 199
 200         # Prevent autoreconf rerun
 201         sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
 202                 "${S}"/project/cmake/modules/FindCpluff.cmake \
 203                 "${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
 204                 "${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \
 205                 || die
 206 }
 207
 208 src_configure() {
 209         local mycmakeargs=(
 210                 -Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
 211                 -DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
 212                 -DENABLE_ALSA=$(usex alsa)
 213                 -DENABLE_AIRTUNES=$(usex airplay)
 214                 -DENABLE_AVAHI=$(usex zeroconf)
 215                 -DENABLE_BLUETOOTH=$(usex bluetooth)
 216                 -DENABLE_BLURAY=$(usex bluray)
 217                 -DENABLE_CCACHE=OFF
 218                 -DENABLE_CEC=$(usex cec)
 219                 -DENABLE_DBUS=$(usex dbus)
 220                 -DENABLE_DVDCSS=$(usex css)
 221                 -DENABLE_INTERNAL_CROSSGUID=OFF
 222                 -DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
 223                 -DENABLE_CAP=$(usex caps)
 224                 -DENABLE_LCMS2=$(usex lcms)
 225                 -DENABLE_LIRC=$(usex lirc)
 226                 -DENABLE_MICROHTTPD=$(usex webserver)
 227                 -DENABLE_MYSQLCLIENT=$(usex mysql "yes" $(usex mariadb))
 228                 -DENABLE_NFS=$(usex nfs)
 229                 -DENABLE_NONFREE=$(usex nonfree)
 230                 -DENABLE_OPENGLES=$(usex gles)
 231                 -DENABLE_OPENGL=$(usex opengl)
 232                 -DENABLE_OPENSSL=ON
 233                 -DENABLE_OPTICAL=$(usex dvd)
 234                 -DENABLE_PLIST=$(usex airplay)
 235                 -DENABLE_PULSEAUDIO=$(usex pulseaudio)
 236                 -DENABLE_SMBCLIENT=$(usex samba)
 237                 -DENABLE_SSH=$(usex sftp)
 238                 -DENABLE_UDEV=$(usex udev)
 239                 -DENABLE_UPNP=$(usex upnp)
 240                 -DENABLE_VAAPI=$(usex vaapi)
 241                 -DENABLE_VDPAU=$(usex vdpau)
 242                 -DENABLE_X11=$(usex X)
 243                 -DENABLE_XSLT=$(usex xslt)
 244                 -Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_COMMIT}.tar.gz"
 245                 -Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_COMMIT}.tar.gz"
 246                 -Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_COMMIT}.tar.gz"
 247         )
 248
 249         use libusb && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
 250
 251         if use system-ffmpeg; then
 252                 mycmakeargs+=( -DWITH_FFMPEG="yes" )
 253         else
 254                 mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz" )
 255         fi
 256
 257         cmake-utils_src_configure
 258 }
 259
 260 src_compile() {
 261         cmake-utils_src_compile all
 262         use test && emake -C "${BUILD_DIR}" kodi-test
 263 }
 264
 265 src_test() {
 266         emake -C "${BUILD_DIR}" test
 267 }
 268
 269 src_install() {
 270         cmake-utils_src_install
 271
 272         pax-mark Em "${ED%/}"/usr/$(get_libdir)/${PN}/${PN}.bin
 273
 274         rm "${ED%/}"/usr/share/doc/*/{LICENSE.GPL,copying.txt}* || die
 275
 276         newicon media/icon48x48.png kodi.png
 277
 278         # Replace bundled fonts with system ones.
 279         rm "${ED%/}"/usr/share/kodi/addons/skin.estouchy/fonts/NotoSans-Regular.ttf || die
 280         dosym ../../../../fonts/noto/NotoSans-Regular.ttf \
 281                 usr/share/kodi/addons/skin.estouchy/fonts/NotoSans-Regular.ttf
 282
 283         local f
 284         for f in NotoMono-Regular.ttf NotoSans-Bold.ttf NotoSans-Regular.ttf ; do
 285                 rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/"${f}" || die
 286                 dosym ../../../../fonts/noto/"${f}" \
 287                         usr/share/kodi/addons/skin.estuary/fonts/"${f}"
 288         done
 289
 290         rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
 291         dosym ../../../../fonts/roboto/Roboto-Thin.ttf \
 292                 usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
 293
 294         python_domodule tools/EventClients/lib/python/xbmcclient.py
 295         python_newscript "tools/EventClients/Clients/Kodi Send/kodi-send.py" kodi-send
 296 }