media-tv/kodi/kodi-17.6.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 # Does not work with py3 here
   7 PYTHON_COMPAT=( python2_7 )
   8 PYTHON_REQ_USE="sqlite"
   9
  10 inherit autotools cmake-utils eutils linux-info pax-utils python-single-r1 versionator
  11
  12 LIBDVDCSS_COMMIT="2f12236bc1c92f73c21e973363f79eb300de603f"
  13 LIBDVDREAD_COMMIT="17d99db97e7b8f23077b342369d3c22a6250affd"
  14 LIBDVDNAV_COMMIT="43b5f81f5fe30bceae3b7cecf2b0ca57fc930dac"
  15 FFMPEG_VERSION="3.1.11"
  16 FFMPEG_KODI_VERSION="17.5"
  17 CODENAME="Krypton"
  18 SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_COMMIT}.tar.gz -> libdvdcss-${LIBDVDCSS_COMMIT}.tar.gz
  19         https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_COMMIT}.tar.gz -> libdvdread-${LIBDVDREAD_COMMIT}.tar.gz
  20         https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_COMMIT}.tar.gz -> libdvdnav-${LIBDVDNAV_COMMIT}.tar.gz
  21         !system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz )"
  22
  23 DESCRIPTION="A free and open source media-player and entertainment hub"
  24 HOMEPAGE="https://kodi.tv/ https://kodi.wiki/"
  25
  26 LICENSE="GPL-2"
  27 SLOT="0"
  28 # use flag is called libusb so that it doesn't fool people in thinking that
  29 # it is _required_ for USB support. Otherwise they'll disable udev and
  30 # that's going to be worse.
  31 IUSE="airplay alsa bluetooth bluray caps cec +css dbus debug dvd gles lcms libressl libusb lirc mysql nfs nonfree +opengl pulseaudio samba sftp systemd +system-ffmpeg test +udev udisks upnp upower vaapi vdpau webserver +X +xslt zeroconf"
  32 REQUIRED_USE="
  33         ${PYTHON_REQUIRED_USE}
  34         || ( gles opengl )
  35         gles? ( X )
  36         opengl? ( X )
  37         udev? ( !libusb )
  38         udisks? ( dbus )
  39         upower? ( dbus )
  40 "
  41
  42 COMMON_DEPEND="${PYTHON_DEPS}
  43         airplay? (
  44                 app-pda/libplist
  45                 net-libs/shairplay
  46         )
  47         alsa? ( media-libs/alsa-lib )
  48         bluetooth? ( net-wireless/bluez )
  49         bluray? ( >=media-libs/libbluray-0.7.0 )
  50         caps? ( sys-libs/libcap )
  51         dbus? ( sys-apps/dbus )
  52         dev-db/sqlite
  53         dev-libs/expat
  54         dev-libs/fribidi
  55         cec? ( >=dev-libs/libcec-4.0 )
  56         dev-libs/libpcre[cxx]
  57         dev-libs/libxml2
  58         >=dev-libs/lzo-2.04
  59         dev-libs/tinyxml[stl]
  60         >=dev-libs/yajl-2
  61         dev-python/pillow[${PYTHON_USEDEP}]
  62         dev-libs/libcdio
  63         gles? ( media-libs/mesa[gles2] )
  64         lcms? ( media-libs/lcms:2 )
  65         libusb? ( virtual/libusb:1 )
  66         media-fonts/corefonts
  67         >=media-fonts/noto-20160531
  68         media-fonts/roboto
  69         media-libs/fontconfig
  70         media-libs/freetype
  71         >=media-libs/libass-0.13.4
  72         media-libs/mesa[egl,X(+)]
  73         >=media-libs/taglib-1.11.1
  74         system-ffmpeg? (
  75                 >=media-video/ffmpeg-${FFMPEG_VERSION}:=[encode,openssl,postproc]
  76                 <media-video/ffmpeg-3.4
  77         )
  78         mysql? ( virtual/mysql )
  79         >=net-misc/curl-7.51.0
  80         nfs? ( net-fs/libnfs:= )
  81         opengl? ( media-libs/glu )
  82         !libressl? ( >=dev-libs/openssl-1.0.2j:0= )
  83         libressl? ( dev-libs/libressl:0= )
  84         pulseaudio? ( media-sound/pulseaudio )
  85         samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
  86         sftp? ( net-libs/libssh[sftp] )
  87         sys-libs/zlib
  88         udev? ( virtual/udev )
  89         vaapi? ( x11-libs/libva[opengl] )
  90         vdpau? (
  91                 || ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
  92                 system-ffmpeg? ( media-video/ffmpeg[vdpau] )
  93         )
  94         webserver? ( >=net-libs/libmicrohttpd-0.9.50[messages] )
  95         X? (
  96                 x11-libs/libdrm
  97                 x11-libs/libX11
  98                 x11-libs/libXrandr
  99                 x11-libs/libXrender
 100         )
 101         xslt? ( dev-libs/libxslt )
 102         zeroconf? ( net-dns/avahi[dbus] )
 103 "
 104 RDEPEND="${COMMON_DEPEND}
 105         lirc? (
 106                 || ( app-misc/lirc app-misc/inputlircd )
 107         )
 108         !media-tv/xbmc
 109         udisks? ( sys-fs/udisks:0 )
 110         upower? ( sys-power/upower )"
 111
 112 DEPEND="${COMMON_DEPEND}
 113         app-arch/bzip2
 114         app-arch/unzip
 115         app-arch/xz-utils
 116         app-arch/zip
 117         dev-lang/swig
 118         dev-libs/crossguid
 119         dev-util/cmake
 120         dev-util/gperf
 121         media-libs/giflib
 122         >=media-libs/libjpeg-turbo-1.5.1:=
 123         >=media-libs/libpng-1.6.26:0=
 124         test? ( dev-cpp/gtest )
 125         virtual/pkgconfig
 126         x86? ( dev-lang/nasm )
 127 "
 128 case ${PV} in
 129 9999)
 130         EGIT_REPO_URI="https://github.com/xbmc/xbmc.git"
 131         inherit git-r3
 132         # Force java for latest git version to avoid having to hand maintain the
 133         # generated addons package.  #488118
 134         DEPEND+="
 135                 virtual/jre
 136                 "
 137         ;;
 138 *)
 139         MY_PV=${PV/_p/_r}
 140         MY_PV=${MY_PV/_alpha/a}
 141         MY_PV=${MY_PV/_beta/b}
 142         MY_PV=${MY_PV/_rc/rc}
 143         MY_P="${PN}-${MY_PV}"
 144         SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}-${CODENAME}.tar.gz -> ${MY_P}.tar.gz
 145                  !java? ( https://github.com/candrews/gentoo-kodi/raw/master/${MY_P}-generated-addons.tar.xz )"
 146         KEYWORDS="~amd64 ~x86"
 147         IUSE+=" java"
 148         DEPEND+="
 149                 java? ( virtual/jre )
 150                 "
 151
 152         S=${WORKDIR}/xbmc-${MY_PV}-${CODENAME}
 153         ;;
 154 esac
 155
 156 CONFIG_CHECK="~IP_MULTICAST"
 157 ERROR_IP_MULTICAST="
 158 In some cases Kodi needs to access multicast addresses.
 159 Please consider enabling IP_MULTICAST under Networking options.
 160 "
 161
 162 CMAKE_USE_DIR=${S}/project/cmake/
 163
 164 pkg_setup() {
 165         check_extra_config
 166         python-single-r1_pkg_setup
 167 }
 168
 169 src_prepare() {
 170         if in_iuse java && use !java; then
 171                 eapply "${FILESDIR}"/${PN}-cmake-no-java.patch
 172         fi
 173         cmake-utils_src_prepare
 174
 175         # avoid long delays when powerkit isn't running #348580
 176         sed -i \
 177                 -e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
 178                 xbmc/linux/*.cpp || die
 179
 180         # Prepare tools and libs witch are configured with autotools during compile time
 181         AUTOTOOLS_DIRS=(
 182                 "${S}"/lib/cpluff
 183                 "${S}"/tools/depends/native/TexturePacker/src
 184                 "${S}"/tools/depends/native/JsonSchemaBuilder/src
 185         )
 186
 187         local d
 188         for d in "${AUTOTOOLS_DIRS[@]}" ; do
 189                 pushd ${d} >/dev/null || die
 190                 AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
 191                 popd >/dev/null || die
 192         done
 193         elibtoolize
 194
 195         # Prevent autoreconf rerun
 196         sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
 197                 "${S}"/project/cmake/modules/FindCpluff.cmake \
 198                 "${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
 199                 "${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \
 200                 || die
 201 }
 202
 203 src_configure() {
 204         local mycmakeargs=(
 205                 -Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
 206                 -DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
 207                 -DENABLE_ALSA=$(usex alsa)
 208                 -DENABLE_AIRTUNES=$(usex airplay)
 209                 -DENABLE_AVAHI=$(usex zeroconf)
 210                 -DENABLE_BLUETOOTH=$(usex bluetooth)
 211                 -DENABLE_BLURAY=$(usex bluray)
 212                 -DENABLE_CCACHE=OFF
 213                 -DENABLE_CEC=$(usex cec)
 214                 -DENABLE_DBUS=$(usex dbus)
 215                 -DENABLE_DVDCSS=$(usex css)
 216                 -DENABLE_INTERNAL_CROSSGUID=OFF
 217                 -DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
 218                 -DENABLE_CAP=$(usex caps)
 219                 -DENABLE_LCMS2=$(usex lcms)
 220                 -DENABLE_LIRC=$(usex lirc)
 221                 -DENABLE_MICROHTTPD=$(usex webserver)
 222                 -DENABLE_MYSQLCLIENT=$(usex mysql "yes" $(usex mariadb))
 223                 -DENABLE_NFS=$(usex nfs)
 224                 -DENABLE_NONFREE=$(usex nonfree)
 225                 -DENABLE_OPENGLES=$(usex gles)
 226                 -DENABLE_OPENGL=$(usex opengl)
 227                 -DENABLE_OPENSSL=ON
 228                 -DENABLE_OPTICAL=$(usex dvd)
 229                 -DENABLE_PLIST=$(usex airplay)
 230                 -DENABLE_PULSEAUDIO=$(usex pulseaudio)
 231                 -DENABLE_SMBCLIENT=$(usex samba)
 232                 -DENABLE_SSH=$(usex sftp)
 233                 -DENABLE_UDEV=$(usex udev)
 234                 -DENABLE_UPNP=$(usex upnp)
 235                 -DENABLE_VAAPI=$(usex vaapi)
 236                 -DENABLE_VDPAU=$(usex vdpau)
 237                 -DENABLE_X11=$(usex X)
 238                 -DENABLE_XSLT=$(usex xslt)
 239                 -Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_COMMIT}.tar.gz"
 240                 -Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_COMMIT}.tar.gz"
 241                 -Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_COMMIT}.tar.gz"
 242         )
 243
 244         use libusb && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
 245
 246         if use system-ffmpeg; then
 247                 mycmakeargs+=( -DWITH_FFMPEG="yes" )
 248         else
 249                 mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz" )
 250         fi
 251
 252         cmake-utils_src_configure
 253 }
 254
 255 src_compile() {
 256         cmake-utils_src_compile all
 257         use test && emake -C "${BUILD_DIR}" kodi-test
 258 }
 259
 260 src_test() {
 261         emake -C "${BUILD_DIR}" test
 262 }
 263
 264 src_install() {
 265         cmake-utils_src_install
 266
 267         pax-mark Em "${ED%/}"/usr/$(get_libdir)/${PN}/${PN}.bin
 268
 269         rm "${ED%/}"/usr/share/doc/*/{LICENSE.GPL,copying.txt}* || die
 270
 271         newicon media/icon48x48.png kodi.png
 272
 273         # Replace bundled fonts with system ones.
 274         rm "${ED%/}"/usr/share/kodi/addons/skin.estouchy/fonts/NotoSans-Regular.ttf || die
 275         dosym ../../../../fonts/noto/NotoSans-Regular.ttf \
 276                 usr/share/kodi/addons/skin.estouchy/fonts/NotoSans-Regular.ttf
 277
 278         local f
 279         for f in NotoMono-Regular.ttf NotoSans-Bold.ttf NotoSans-Regular.ttf ; do
 280                 rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/"${f}" || die
 281                 dosym ../../../../fonts/noto/"${f}" \
 282                         usr/share/kodi/addons/skin.estuary/fonts/"${f}"
 283         done
 284
 285         rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
 286         dosym ../../../../fonts/roboto/Roboto-Thin.ttf \
 287                 usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
 288
 289         python_domodule tools/EventClients/lib/python/xbmcclient.py
 290         python_newscript "tools/EventClients/Clients/Kodi Send/kodi-send.py" kodi-send
 291 }