media-tv/kodi/kodi-17.6-r6.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 # Does not work with py3 here
   7 PYTHON_COMPAT=( python2_7 )
   8 PYTHON_REQ_USE="sqlite"
   9
  10 inherit autotools cmake-utils eutils linux-info pax-utils python-single-r1 versionator
  11
  12 LIBDVDCSS_COMMIT="2f12236bc1c92f73c21e973363f79eb300de603f"
  13 LIBDVDREAD_COMMIT="17d99db97e7b8f23077b342369d3c22a6250affd"
  14 LIBDVDNAV_COMMIT="43b5f81f5fe30bceae3b7cecf2b0ca57fc930dac"
  15 FFMPEG_VERSION="3.1.11"
  16 FFMPEG_KODI_VERSION="17.5"
  17 CODENAME="Krypton"
  18 PATCHES=(
  19         "${FILESDIR}/${P}-nmblookup.patch"
  20 )
  21 SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_COMMIT}.tar.gz -> libdvdcss-${LIBDVDCSS_COMMIT}.tar.gz
  22         https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_COMMIT}.tar.gz -> libdvdread-${LIBDVDREAD_COMMIT}.tar.gz
  23         https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_COMMIT}.tar.gz -> libdvdnav-${LIBDVDNAV_COMMIT}.tar.gz
  24         !system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz )"
  25
  26 DESCRIPTION="A free and open source media-player and entertainment hub"
  27 HOMEPAGE="https://kodi.tv/ https://kodi.wiki/"
  28
  29 LICENSE="GPL-2"
  30 SLOT="0"
  31 # use flag is called libusb so that it doesn't fool people in thinking that
  32 # it is _required_ for USB support. Otherwise they'll disable udev and
  33 # that's going to be worse.
  34 IUSE="airplay alsa bluetooth bluray caps cec +css dbus debug dvd gles lcms libressl libusb lirc mariadb mysql nfs nonfree +opengl pulseaudio samba sftp systemd +system-ffmpeg test +udev udisks upnp upower vaapi vdpau webserver +xslt zeroconf"
  35 REQUIRED_USE="
  36         ${PYTHON_REQUIRED_USE}
  37         || ( gles opengl )
  38         ?? ( mariadb mysql )
  39         udev? ( !libusb )
  40         udisks? ( dbus )
  41         upower? ( dbus )
  42 "
  43
  44 COMMON_DEPEND="${PYTHON_DEPS}
  45         airplay? (
  46                 app-pda/libplist
  47                 net-libs/shairplay
  48         )
  49         alsa? ( media-libs/alsa-lib )
  50         bluetooth? ( net-wireless/bluez )
  51         bluray? ( >=media-libs/libbluray-0.7.0 )
  52         caps? ( sys-libs/libcap )
  53         dbus? ( sys-apps/dbus )
  54         dev-db/sqlite
  55         dev-libs/expat
  56         dev-libs/fribidi
  57         cec? ( >=dev-libs/libcec-4.0 )
  58         dev-libs/libpcre[cxx]
  59         dev-libs/libxml2
  60         >=dev-libs/lzo-2.04
  61         dev-libs/tinyxml[stl]
  62         >=dev-libs/yajl-2
  63         dev-python/pillow[${PYTHON_USEDEP}]
  64         dev-libs/libcdio
  65         gles? ( media-libs/mesa[gles2] )
  66         lcms? ( media-libs/lcms:2 )
  67         libusb? ( virtual/libusb:1 )
  68         virtual/ttf-fonts
  69         >=media-fonts/noto-20160531
  70         media-fonts/roboto
  71         media-libs/fontconfig
  72         media-libs/freetype
  73         >=media-libs/libass-0.13.4
  74         media-libs/mesa[egl]
  75         >=media-libs/taglib-1.11.1
  76         system-ffmpeg? (
  77                 >=media-video/ffmpeg-${FFMPEG_VERSION}:=[encode,openssl,postproc]
  78                 <media-video/ffmpeg-3.4
  79         )
  80         mysql? (
  81                 !mariadb? ( dev-db/mysql-connector-c:= )
  82                 mariadb? ( dev-db/mariadb-connector-c:=[mysqlcompat] )
  83         )
  84         >=net-misc/curl-7.51.0
  85         nfs? ( net-fs/libnfs:= )
  86         opengl? ( media-libs/glu )
  87         !libressl? ( >=dev-libs/openssl-1.0.2j:0= )
  88         libressl? ( dev-libs/libressl:0= )
  89         pulseaudio? ( media-sound/pulseaudio )
  90         samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
  91         sftp? ( net-libs/libssh[sftp] )
  92         sys-libs/zlib
  93         udev? ( virtual/udev )
  94         vaapi? ( x11-libs/libva:=[opengl] )
  95         vdpau? (
  96                 || ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
  97                 system-ffmpeg? ( media-video/ffmpeg[vdpau] )
  98         )
  99         webserver? ( >=net-libs/libmicrohttpd-0.9.50[messages] )
 100         xslt? ( dev-libs/libxslt )
 101         zeroconf? ( net-dns/avahi[dbus] )
 102 "
 103 RDEPEND="${COMMON_DEPEND}
 104         lirc? (
 105                 || ( app-misc/lirc app-misc/inputlircd )
 106         )
 107         !media-tv/xbmc
 108         udisks? ( sys-fs/udisks:0 )
 109         upower? ( sys-power/upower )"
 110
 111 DEPEND="${COMMON_DEPEND}
 112         app-arch/bzip2
 113         app-arch/unzip
 114         app-arch/xz-utils
 115         app-arch/zip
 116         dev-lang/swig
 117         dev-libs/crossguid
 118         dev-util/cmake
 119         dev-util/gperf
 120         media-libs/giflib
 121         >=media-libs/libjpeg-turbo-1.5.1:=
 122         >=media-libs/libpng-1.6.26:0=
 123         test? ( dev-cpp/gtest )
 124         virtual/pkgconfig
 125         x86? ( dev-lang/nasm )
 126 "
 127 case ${PV} in
 128 9999)
 129         EGIT_REPO_URI="https://github.com/xbmc/xbmc.git"
 130         inherit git-r3
 131         # Force java for latest git version to avoid having to hand maintain the
 132         # generated addons package.  #488118
 133         DEPEND+="
 134                 virtual/jre
 135                 "
 136         ;;
 137 *)
 138         MY_PV=${PV/_p/_r}
 139         MY_PV=${MY_PV/_alpha/a}
 140         MY_PV=${MY_PV/_beta/b}
 141         MY_PV=${MY_PV/_rc/rc}
 142         MY_P="${PN}-${MY_PV}"
 143         SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}-${CODENAME}.tar.gz -> ${MY_P}.tar.gz
 144                  !java? ( https://github.com/candrews/gentoo-kodi/raw/master/${MY_P}-generated-addons.tar.xz )"
 145         KEYWORDS="~amd64 ~x86"
 146         IUSE+=" java"
 147         DEPEND+="
 148                 java? ( virtual/jre )
 149                 "
 150
 151         S=${WORKDIR}/xbmc-${MY_PV}-${CODENAME}
 152         ;;
 153 esac
 154
 155 CONFIG_CHECK="~IP_MULTICAST"
 156 ERROR_IP_MULTICAST="
 157 In some cases Kodi needs to access multicast addresses.
 158 Please consider enabling IP_MULTICAST under Networking options.
 159 "
 160
 161 CMAKE_USE_DIR=${S}/project/cmake/
 162
 163 pkg_setup() {
 164         check_extra_config
 165         python-single-r1_pkg_setup
 166 }
 167
 168 src_prepare() {
 169         if in_iuse java && use !java; then
 170                 eapply "${FILESDIR}"/${PN}-cmake-no-java.patch
 171         fi
 172         cmake-utils_src_prepare
 173
 174         # avoid long delays when powerkit isn't running #348580
 175         sed -i \
 176                 -e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
 177                 xbmc/linux/*.cpp || die
 178
 179         # Prepare tools and libs witch are configured with autotools during compile time
 180         AUTOTOOLS_DIRS=(
 181                 "${S}"/lib/cpluff
 182                 "${S}"/tools/depends/native/TexturePacker/src
 183                 "${S}"/tools/depends/native/JsonSchemaBuilder/src
 184         )
 185
 186         local d
 187         for d in "${AUTOTOOLS_DIRS[@]}" ; do
 188                 pushd ${d} >/dev/null || die
 189                 AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
 190                 popd >/dev/null || die
 191         done
 192         elibtoolize
 193
 194         # Prevent autoreconf rerun
 195         sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
 196                 "${S}"/project/cmake/modules/FindCpluff.cmake \
 197                 "${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
 198                 "${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \
 199                 || die
 200 }
 201
 202 src_configure() {
 203         local mycmakeargs=(
 204                 -Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
 205                 -DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
 206                 -DENABLE_ALSA=$(usex alsa)
 207                 -DENABLE_AIRTUNES=$(usex airplay)
 208                 -DENABLE_AVAHI=$(usex zeroconf)
 209                 -DENABLE_BLUETOOTH=$(usex bluetooth)
 210                 -DENABLE_BLURAY=$(usex bluray)
 211                 -DENABLE_CCACHE=OFF
 212                 -DENABLE_CEC=$(usex cec)
 213                 -DENABLE_DBUS=$(usex dbus)
 214                 -DENABLE_DVDCSS=$(usex css)
 215                 -DENABLE_INTERNAL_CROSSGUID=OFF
 216                 -DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
 217                 -DENABLE_CAP=$(usex caps)
 218                 -DENABLE_LCMS2=$(usex lcms)
 219                 -DENABLE_LIRC=$(usex lirc)
 220                 -DENABLE_MICROHTTPD=$(usex webserver)
 221                 -DENABLE_MYSQLCLIENT=$(usex mysql)
 222                 -DENABLE_NFS=$(usex nfs)
 223                 -DENABLE_NONFREE=$(usex nonfree)
 224                 -DENABLE_OPENGLES=$(usex gles)
 225                 -DENABLE_OPENGL=$(usex opengl)
 226                 -DENABLE_OPENSSL=ON
 227                 -DENABLE_OPTICAL=$(usex dvd)
 228                 -DENABLE_PLIST=$(usex airplay)
 229                 -DENABLE_PULSEAUDIO=$(usex pulseaudio)
 230                 -DENABLE_SMBCLIENT=$(usex samba)
 231                 -DENABLE_SSH=$(usex sftp)
 232                 -DENABLE_UDEV=$(usex udev)
 233                 -DENABLE_UPNP=$(usex upnp)
 234                 -DENABLE_VAAPI=$(usex vaapi)
 235                 -DENABLE_VDPAU=$(usex vdpau)
 236                 -DENABLE_X11=ON
 237                 -DENABLE_XSLT=$(usex xslt)
 238                 -Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_COMMIT}.tar.gz"
 239                 -Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_COMMIT}.tar.gz"
 240                 -Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_COMMIT}.tar.gz"
 241         )
 242
 243         use libusb && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
 244
 245         if use system-ffmpeg; then
 246                 mycmakeargs+=( -DWITH_FFMPEG="yes" )
 247         else
 248                 mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz" )
 249         fi
 250
 251         cmake-utils_src_configure
 252 }
 253
 254 src_compile() {
 255         cmake-utils_src_compile all
 256         use test && emake -C "${BUILD_DIR}" kodi-test
 257 }
 258
 259 src_test() {
 260         emake -C "${BUILD_DIR}" test
 261 }
 262
 263 src_install() {
 264         cmake-utils_src_install
 265
 266         pax-mark Em "${ED%/}"/usr/$(get_libdir)/${PN}/${PN}.bin
 267
 268         rm "${ED%/}"/usr/share/doc/*/{LICENSE.GPL,copying.txt}* || die
 269
 270         newicon media/icon48x48.png kodi.png
 271
 272         # Replace bundled fonts with system ones.
 273         rm "${ED%/}"/usr/share/kodi/addons/skin.estouchy/fonts/NotoSans-Regular.ttf || die
 274         dosym ../../../../fonts/noto/NotoSans-Regular.ttf \
 275                 usr/share/kodi/addons/skin.estouchy/fonts/NotoSans-Regular.ttf
 276
 277         local f
 278         for f in NotoMono-Regular.ttf NotoSans-Bold.ttf NotoSans-Regular.ttf ; do
 279                 rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/"${f}" || die
 280                 dosym ../../../../fonts/noto/"${f}" \
 281                         usr/share/kodi/addons/skin.estuary/fonts/"${f}"
 282         done
 283
 284         rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
 285         dosym ../../../../fonts/roboto/Roboto-Thin.ttf \
 286                 usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
 287
 288         python_domodule tools/EventClients/lib/python/xbmcclient.py
 289         python_newscript "tools/EventClients/Clients/Kodi Send/kodi-send.py" kodi-send
 290 }