media-tv/kodi/kodi-17.3.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 # Does not work with py3 here
   7 PYTHON_COMPAT=( python2_7 )
   8 PYTHON_REQ_USE="sqlite"
   9
  10 inherit autotools cmake-utils eutils linux-info pax-utils python-single-r1
  11
  12 LIBDVDCSS_COMMIT="2f12236bc1c92f73c21e973363f79eb300de603f"
  13 LIBDVDREAD_COMMIT="17d99db97e7b8f23077b342369d3c22a6250affd"
  14 LIBDVDNAV_COMMIT="43b5f81f5fe30bceae3b7cecf2b0ca57fc930dac"
  15 FFMPEG_VERSION="3.1.6"
  16 CODENAME="Krypton"
  17 SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_COMMIT}.tar.gz -> libdvdcss-${LIBDVDCSS_COMMIT}.tar.gz
  18         https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_COMMIT}.tar.gz -> libdvdread-${LIBDVDREAD_COMMIT}.tar.gz
  19         https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_COMMIT}.tar.gz -> libdvdnav-${LIBDVDNAV_COMMIT}.tar.gz
  20         !system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}.tar.gz )"
  21
  22 DESCRIPTION="Kodi is a free and open source media-player and entertainment hub"
  23 HOMEPAGE="https://kodi.tv/ http://kodi.wiki/"
  24
  25 LICENSE="GPL-2"
  26 SLOT="0"
  27 # use flag is called libusb so that it doesn't fool people in thinking that
  28 # it is _required_ for USB support. Otherwise they'll disable udev and
  29 # that's going to be worse.
  30 IUSE="airplay alsa bluetooth bluray caps cec +css dbus debug dvd gles libressl libusb lirc mysql nfs nonfree +opengl pulseaudio samba sftp systemd +system-ffmpeg test +udev udisks upnp upower vaapi vdpau webserver +X +xslt zeroconf"
  31 REQUIRED_USE="
  32         ${PYTHON_REQUIRED_USE}
  33         || ( gles opengl )
  34         gles? ( X )
  35         opengl? ( X )
  36         udev? ( !libusb )
  37         udisks? ( dbus )
  38         upower? ( dbus )
  39 "
  40
  41 COMMON_DEPEND="${PYTHON_DEPS}
  42         airplay? (
  43                 app-pda/libplist
  44                 net-libs/shairplay
  45         )
  46         alsa? ( media-libs/alsa-lib )
  47         bluetooth? ( net-wireless/bluez )
  48         bluray? ( >=media-libs/libbluray-0.7.0 )
  49         caps? ( sys-libs/libcap )
  50         dbus? ( sys-apps/dbus )
  51         dev-db/sqlite
  52         dev-libs/expat
  53         dev-libs/fribidi
  54         cec? ( >=dev-libs/libcec-4.0 )
  55         dev-libs/libpcre[cxx]
  56         dev-libs/libxml2
  57         >=dev-libs/lzo-2.04
  58         dev-libs/tinyxml[stl]
  59         >=dev-libs/yajl-2
  60         dev-python/pillow[${PYTHON_USEDEP}]
  61         dev-libs/libcdio
  62         gles? ( media-libs/mesa[gles2] )
  63         libusb? ( virtual/libusb:1 )
  64         media-fonts/corefonts
  65         >=media-fonts/noto-20160531
  66         media-fonts/roboto
  67         media-libs/fontconfig
  68         media-libs/freetype
  69         >=media-libs/libass-0.13.4
  70         media-libs/mesa[egl]
  71         >=media-libs/taglib-1.11.1
  72         system-ffmpeg? ( >=media-video/ffmpeg-${FFMPEG_VERSION}:=[encode,postproc] )
  73         mysql? ( virtual/mysql )
  74         >=net-misc/curl-7.51.0
  75         nfs? ( net-fs/libnfs:= )
  76         opengl? ( media-libs/glu )
  77         !libressl? ( >=dev-libs/openssl-1.0.2j:0= )
  78         libressl? ( dev-libs/libressl:0= )
  79         pulseaudio? ( media-sound/pulseaudio )
  80         samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
  81         sftp? ( net-libs/libssh[sftp] )
  82         sys-libs/zlib
  83         udev? ( virtual/udev )
  84         vaapi? ( x11-libs/libva[opengl] )
  85         vdpau? (
  86                 || ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
  87                 system-ffmpeg? ( media-video/ffmpeg[vdpau] )
  88         )
  89         webserver? ( >=net-libs/libmicrohttpd-0.9.50[messages] )
  90         X? (
  91                 x11-libs/libdrm
  92                 x11-libs/libX11
  93                 x11-libs/libXrandr
  94                 x11-libs/libXrender
  95         )
  96         xslt? ( dev-libs/libxslt )
  97         zeroconf? ( net-dns/avahi[dbus] )
  98 "
  99 RDEPEND="${COMMON_DEPEND}
 100         lirc? (
 101                 || ( app-misc/lirc app-misc/inputlircd )
 102         )
 103         !media-tv/xbmc
 104         udisks? ( sys-fs/udisks:0 )
 105         upower? (
 106                 systemd? ( sys-power/upower )
 107                 !systemd? (
 108                         || ( sys-power/upower-pm-utils sys-power/upower )
 109                 )
 110         )
 111 "
 112 DEPEND="${COMMON_DEPEND}
 113         app-arch/bzip2
 114         app-arch/unzip
 115         app-arch/xz-utils
 116         app-arch/zip
 117         dev-lang/swig
 118         dev-libs/crossguid
 119         dev-util/cmake
 120         dev-util/gperf
 121         media-libs/giflib
 122         >=media-libs/libjpeg-turbo-1.5.1:=
 123         >=media-libs/libpng-1.6.26:0=
 124         test? ( dev-cpp/gtest )
 125         virtual/pkgconfig
 126         x86? ( dev-lang/nasm )
 127 "
 128 case ${PV} in
 129 9999)
 130         EGIT_REPO_URI="git://github.com/xbmc/xbmc.git"
 131         inherit git-r3
 132         # Force java for latest git version to avoid having to hand maintain the
 133         # generated addons package.  #488118
 134         DEPEND+="
 135                 virtual/jre
 136                 "
 137         ;;
 138 *)
 139         MY_PV=${PV/_p/_r}
 140         MY_PV=${MY_PV/_alpha/a}
 141         MY_PV=${MY_PV/_beta/b}
 142         MY_PV=${MY_PV/_rc/rc}
 143         MY_P="${PN}-${MY_PV}"
 144         SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}-${CODENAME}.tar.gz -> ${MY_P}.tar.gz
 145                  !java? ( https://github.com/candrews/gentoo-kodi/raw/master/${MY_P}-generated-addons.tar.xz )"
 146         KEYWORDS="amd64 ~x86"
 147         IUSE+=" java"
 148         DEPEND+="
 149                 java? ( virtual/jre )
 150                 "
 151
 152         S=${WORKDIR}/xbmc-${MY_PV}-${CODENAME}
 153         ;;
 154 esac
 155
 156 CONFIG_CHECK="~IP_MULTICAST"
 157 ERROR_IP_MULTICAST="
 158 In some cases Kodi needs to access multicast addresses.
 159 Please consider enabling IP_MULTICAST under Networking options.
 160 "
 161
 162 CMAKE_USE_DIR=${S}/project/cmake/
 163
 164 pkg_setup() {
 165         check_extra_config
 166         python-single-r1_pkg_setup
 167 }
 168
 169 src_prepare() {
 170         if in_iuse java && use !java; then
 171                 eapply "${FILESDIR}"/${PN}-cmake-no-java.patch
 172         fi
 173         cmake-utils_src_prepare
 174
 175         # avoid long delays when powerkit isn't running #348580
 176         sed -i \
 177                 -e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
 178                 xbmc/linux/*.cpp || die
 179
 180         # Prepare tools and libs witch are configured with autotools during compile time
 181         AUTOTOOLS_DIRS=(
 182                 "${S}"/lib/cpluff
 183                 "${S}"/tools/depends/native/TexturePacker/src
 184                 "${S}"/tools/depends/native/JsonSchemaBuilder/src
 185         )
 186
 187         local d
 188         for d in "${AUTOTOOLS_DIRS[@]}" ; do
 189                 pushd ${d} >/dev/null || die
 190                 AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
 191                 popd >/dev/null || die
 192         done
 193         elibtoolize
 194
 195         # Prevent autoreconf rerun
 196         sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
 197                 "${S}"/project/cmake/modules/FindCpluff.cmake \
 198                 "${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
 199                 "${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \
 200                 || die
 201 }
 202
 203 src_configure() {
 204         local mycmakeargs=(
 205                 -Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
 206                 -DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
 207                 -DENABLE_ALSA=$(usex alsa)
 208                 -DENABLE_AIRTUNES=$(usex airplay)
 209                 -DENABLE_AVAHI=$(usex zeroconf)
 210                 -DENABLE_BLUETOOTH=$(usex bluetooth)
 211                 -DENABLE_BLURAY=$(usex bluray)
 212                 -DENABLE_CCACHE=OFF
 213                 -DENABLE_CEC=$(usex cec)
 214                 -DENABLE_DBUS=$(usex dbus)
 215                 -DENABLE_DVDCSS=$(usex css)
 216                 -DENABLE_INTERNAL_CROSSGUID=OFF
 217                 -DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
 218                 -DENABLE_CAP=$(usex caps)
 219                 -DENABLE_LIRC=$(usex lirc)
 220                 -DENABLE_MICROHTTPD=$(usex webserver)
 221                 -DENABLE_MYSQLCLIENT=$(usex mysql)
 222                 -DENABLE_NFS=$(usex nfs)
 223                 -DENABLE_NONFREE=$(usex nonfree)
 224                 -DENABLE_OPENGLES=$(usex gles)
 225                 -DENABLE_OPENGL=$(usex opengl)
 226                 -DENABLE_OPENSSL=ON
 227                 -DENABLE_OPTICAL=$(usex dvd)
 228                 -DENABLE_PLIST=$(usex airplay)
 229                 -DENABLE_PULSEAUDIO=$(usex pulseaudio)
 230                 -DENABLE_SMBCLIENT=$(usex samba)
 231                 -DENABLE_SSH=$(usex sftp)
 232                 -DENABLE_UDEV=$(usex udev)
 233                 -DENABLE_UPNP=$(usex upnp)
 234                 -DENABLE_VAAPI=$(usex vaapi)
 235                 -DENABLE_VDPAU=$(usex vdpau)
 236                 -DENABLE_X11=$(usex X)
 237                 -DENABLE_XSLT=$(usex xslt)
 238                 -Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_COMMIT}.tar.gz"
 239                 -Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_COMMIT}.tar.gz"
 240                 -Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_COMMIT}.tar.gz"
 241         )
 242
 243         use libusb && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
 244
 245         use !system-ffmpeg && mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}.tar.gz" )
 246
 247         cmake-utils_src_configure
 248 }
 249
 250 src_compile() {
 251         cmake-utils_src_compile all $(usev test)
 252 }
 253
 254 src_install() {
 255         cmake-utils_src_install
 256
 257         pax-mark Em "${ED%/}"/usr/$(get_libdir)/${PN}/${PN}.bin
 258
 259         rm "${ED%/}"/usr/share/doc/*/{LICENSE.GPL,copying.txt}* || die
 260
 261         newicon media/icon48x48.png kodi.png
 262
 263         # Replace bundled fonts with system ones.
 264         rm "${ED%/}"/usr/share/kodi/addons/skin.estouchy/fonts/NotoSans-Regular.ttf || die
 265         dosym ../../../../fonts/noto/NotoSans-Regular.ttf \
 266                 usr/share/kodi/addons/skin.estouchy/fonts/NotoSans-Regular.ttf
 267
 268         local f
 269         for f in NotoMono-Regular.ttf NotoSans-Bold.ttf NotoSans-Regular.ttf ; do
 270                 rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/"${f}" || die
 271                 dosym ../../../../fonts/noto/"${f}" \
 272                         usr/share/kodi/addons/skin.estuary/fonts/"${f}"
 273         done
 274
 275         rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
 276         dosym ../../../../fonts/roboto/Roboto-Thin.ttf \
 277                 usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
 278
 279         python_domodule tools/EventClients/lib/python/xbmcclient.py
 280         python_newscript "tools/EventClients/Clients/Kodi Send/kodi-send.py" kodi-send
 281 }