media-tv/kodi/kodi-17.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 # Does not work with py3 here
   8 PYTHON_COMPAT=( python2_7 )
   9 PYTHON_REQ_USE="sqlite"
  10
  11 inherit eutils linux-info python-single-r1 cmake-utils autotools
  12
  13 LIBDVDCSS_COMMIT="2f12236bc1c92f73c21e973363f79eb300de603f"
  14 LIBDVDREAD_COMMIT="17d99db97e7b8f23077b342369d3c22a6250affd"
  15 LIBDVDNAV_COMMIT="43b5f81f5fe30bceae3b7cecf2b0ca57fc930dac"
  16 CODENAME="Krypton"
  17 SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_COMMIT}.tar.gz -> libdvdcss-${LIBDVDCSS_COMMIT}.tar.gz
  18         https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_COMMIT}.tar.gz -> libdvdread-${LIBDVDREAD_COMMIT}.tar.gz
  19         https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_COMMIT}.tar.gz -> libdvdnav-${LIBDVDNAV_COMMIT}.tar.gz"
  20
  21 DESCRIPTION="Kodi is a free and open source media-player and entertainment hub"
  22 HOMEPAGE="https://kodi.tv/ http://kodi.wiki/"
  23
  24 LICENSE="GPL-2"
  25 SLOT="0"
  26 # use flag is called libusb so that it doesn't fool people in thinking that
  27 # it is _required_ for USB support. Otherwise they'll disable udev and
  28 # that's going to be worse.
  29 IUSE="airplay alsa bluetooth bluray caps cec +css dbus debug dvd gles libressl libusb lirc mysql nfs nonfree +opengl +ssl pulseaudio samba sftp systemd test +udev udisks upnp upower vaapi vdpau webserver +X +xslt zeroconf"
  30 REQUIRED_USE="
  31         ${PYTHON_REQUIRED_USE}
  32         || ( gles opengl )
  33         udev? ( !libusb )
  34         udisks? ( dbus )
  35         upower? ( dbus )
  36 "
  37
  38 COMMON_DEPEND="${PYTHON_DEPS}
  39         airplay? (
  40                 app-pda/libplist
  41                 net-libs/shairplay
  42         )
  43         alsa? ( media-libs/alsa-lib )
  44         bluetooth? ( net-wireless/bluez )
  45         bluray? ( >=media-libs/libbluray-0.7.0 )
  46         caps? ( sys-libs/libcap )
  47         dbus? ( sys-apps/dbus )
  48         dev-db/sqlite
  49         dev-libs/expat
  50         dev-libs/fribidi
  51         cec? ( >=dev-libs/libcec-4.0 )
  52         dev-libs/libpcre[cxx]
  53         dev-libs/libxml2
  54         >=dev-libs/lzo-2.04
  55         dev-libs/tinyxml[stl]
  56         >=dev-libs/yajl-2
  57         dev-python/pillow[${PYTHON_USEDEP}]
  58         dev-libs/libcdio
  59         gles? ( media-libs/mesa[gles2] )
  60         libusb? ( virtual/libusb:1 )
  61         media-fonts/corefonts
  62         >=media-fonts/noto-20160531
  63         media-fonts/roboto
  64         media-libs/fontconfig
  65         media-libs/freetype
  66         >=media-libs/libass-0.13.4
  67         media-libs/mesa[egl]
  68         >=media-libs/taglib-1.11.1
  69         >=media-video/ffmpeg-3.1.6:=[encode]
  70         mysql? ( virtual/mysql )
  71         >=net-misc/curl-7.51.0
  72         nfs? ( net-fs/libnfs:= )
  73         opengl? ( media-libs/glu )
  74         ssl? (
  75                 !libressl? ( >=dev-libs/openssl-1.0.2j:0= )
  76                 libressl? ( dev-libs/libressl:0= )
  77         )
  78         pulseaudio? ( media-sound/pulseaudio )
  79         samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
  80         sftp? ( net-libs/libssh[sftp] )
  81         sys-libs/zlib
  82         udev? ( virtual/udev )
  83         vaapi? ( x11-libs/libva[opengl] )
  84         vdpau? (
  85                 || ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
  86                 media-video/ffmpeg[vdpau]
  87         )
  88         webserver? ( >=net-libs/libmicrohttpd-0.9.50[messages] )
  89         X? (
  90                 x11-libs/libdrm
  91                 x11-libs/libX11
  92                 x11-libs/libXrandr
  93                 x11-libs/libXrender
  94         )
  95         xslt? ( dev-libs/libxslt )
  96         zeroconf? ( net-dns/avahi[dbus] )
  97 "
  98 RDEPEND="${COMMON_DEPEND}
  99         lirc? (
 100                 || ( app-misc/lirc app-misc/inputlircd )
 101         )
 102         !media-tv/xbmc
 103         udisks? ( sys-fs/udisks:0 )
 104         upower? (
 105                 systemd? ( sys-power/upower )
 106                 !systemd? (
 107                         || ( sys-power/upower-pm-utils sys-power/upower )
 108                 )
 109         )
 110 "
 111 DEPEND="${COMMON_DEPEND}
 112         app-arch/bzip2
 113         app-arch/unzip
 114         app-arch/xz-utils
 115         app-arch/zip
 116         dev-lang/swig
 117         dev-libs/crossguid
 118         dev-util/cmake
 119         dev-util/gperf
 120         media-libs/giflib
 121         >=media-libs/libjpeg-turbo-1.5.1:=
 122         >=media-libs/libpng-1.6.26:0=
 123         test? ( dev-cpp/gtest )
 124         virtual/pkgconfig
 125         x86? ( dev-lang/nasm )
 126 "
 127 case ${PV} in
 128 9999)
 129         EGIT_REPO_URI="git://github.com/xbmc/xbmc.git"
 130         inherit git-r3
 131         # Force java for latest git version to avoid having to hand maintain the
 132         # generated addons package.  #488118
 133         DEPEND+="
 134                 virtual/jre
 135                 "
 136         ;;
 137 *)
 138         MY_PV=${PV/_p/_r}
 139         MY_PV=${MY_PV/_alpha/a}
 140         MY_PV=${MY_PV/_beta/b}
 141         MY_PV=${MY_PV/_rc/rc}
 142         MY_P="${PN}-${MY_PV}"
 143         SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}-${CODENAME}.tar.gz -> ${MY_P}.tar.gz
 144                  !java? ( https://github.com/candrews/gentoo-kodi/raw/master/${MY_P}-generated-addons.tar.xz )"
 145         KEYWORDS="~amd64 ~x86"
 146         IUSE+=" java"
 147         DEPEND+="
 148                 java? ( virtual/jre )
 149                 "
 150
 151         S=${WORKDIR}/xbmc-${MY_PV}-${CODENAME}
 152         ;;
 153 esac
 154
 155 CONFIG_CHECK="~IP_MULTICAST"
 156 ERROR_IP_MULTICAST="
 157 In some cases Kodi needs to access multicast addresses.
 158 Please consider enabling IP_MULTICAST under Networking options.
 159 "
 160
 161 CMAKE_USE_DIR=${S}/project/cmake/
 162
 163 pkg_setup() {
 164         check_extra_config
 165         python-single-r1_pkg_setup
 166 }
 167
 168 src_prepare() {
 169         if in_iuse java && use !java; then
 170                 eapply "${FILESDIR}"/${PN}-cmake-no-java.patch
 171         fi
 172         cmake-utils_src_prepare
 173
 174         # avoid long delays when powerkit isn't running #348580
 175         sed -i \
 176                 -e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
 177                 xbmc/linux/*.cpp || die
 178
 179         # Prepare tools and libs witch are configured with autotools during compile time
 180         AUTOTOOLS_DIRS=(
 181                 "${S}"/lib/cpluff
 182                 "${S}"/tools/depends/native/TexturePacker/src
 183                 "${S}"/tools/depends/native/JsonSchemaBuilder/src
 184         )
 185
 186         local d
 187         for d in "${AUTOTOOLS_DIRS[@]}" ; do
 188                 pushd ${d} >/dev/null || die
 189                 AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
 190                 popd >/dev/null || die
 191         done
 192         elibtoolize
 193
 194         # Prevent autoreconf rerun
 195         sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
 196                 "${S}"/project/cmake/modules/FindCpluff.cmake \
 197                 "${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
 198                 "${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh
 199 }
 200
 201 src_configure() {
 202         local CMAKE_BUILD_TYPE=$(usex debug Debug RelWithDebInfo)
 203
 204         local mycmakeargs=(
 205                 -Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
 206                 -DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
 207                 -DENABLE_ALSA=$(usex alsa)
 208                 -DENABLE_AIRTUNES=$(usex airplay)
 209                 -DENABLE_AVAHI=$(usex zeroconf)
 210                 -DENABLE_BLUETOOTH=$(usex bluetooth)
 211                 -DENABLE_BLURAY=$(usex bluray)
 212                 -DENABLE_CCACHE=OFF
 213                 -DENABLE_CEC=$(usex cec)
 214                 -DENABLE_DBUS=$(usex dbus)
 215                 -DENABLE_DVDCSS=$(usex css)
 216                 -DENABLE_INTERNAL_CROSSGUID=OFF
 217                 -DENABLE_INTERNAL_FFMPEG=OFF
 218                 -DENABLE_CAP=$(usex caps)
 219                 -DENABLE_LIRC=$(usex lirc)
 220                 -DENABLE_MICROHTTPD=$(usex webserver)
 221                 -DENABLE_MYSQLCLIENT=$(usex mysql)
 222                 -DENABLE_NFS=$(usex nfs)
 223                 -DENABLE_NONFREE=$(usex nonfree)
 224                 -DENABLE_OPENGLES=$(usex gles)
 225                 -DENABLE_OPENGL=$(usex opengl)
 226                 -DENABLE_OPENSSL=$(usex ssl)
 227                 -DENABLE_OPTICAL=$(usex dvd)
 228                 -DENABLE_PLIST=$(usex airplay)
 229                 -DENABLE_PULSEAUDIO=$(usex pulseaudio)
 230                 -DENABLE_SMBCLIENT=$(usex samba)
 231                 -DENABLE_SSH=$(usex sftp)
 232                 -DENABLE_UDEV=$(usex udev)
 233                 -DENABLE_UPNP=$(usex upnp)
 234                 -DENABLE_VAAPI=$(usex vaapi)
 235                 -DENABLE_VDPAU=$(usex vdpau)
 236                 -DENABLE_X11=$(usex X)
 237                 -DENABLE_XSLT=$(usex xslt)
 238                 -Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_COMMIT}.tar.gz"
 239                 -Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_COMMIT}.tar.gz"
 240                 -Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_COMMIT}.tar.gz"
 241         )
 242
 243         use libusb && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
 244
 245         cmake-utils_src_configure
 246 }
 247
 248 src_compile() {
 249         cmake-utils_src_compile all $(usev test)
 250 }
 251
 252 src_install() {
 253         cmake-utils_src_install
 254         rm "${ED%/}"/usr/share/doc/*/{LICENSE.GPL,copying.txt}* || die
 255
 256         newicon media/icon48x48.png kodi.png
 257
 258         # Replace bundled fonts with system ones.
 259         rm "${ED%/}"/usr/share/kodi/addons/skin.estouchy/fonts/NotoSans-Regular.ttf || die
 260         dosym /usr/share/fonts/noto/NotoSans-Regular.ttf \
 261                 usr/share/kodi/addons/skin.estouchy/fonts/NotoSans-Regular.ttf
 262
 263         local f
 264         for f in NotoMono-Regular.ttf NotoSans-Bold.ttf NotoSans-Regular.ttf ; do
 265                 rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/"${f}" || die
 266                 dosym /usr/share/fonts/noto/"${f}" \
 267                         usr/share/kodi/addons/skin.estuary/fonts/"${f}"
 268         done
 269
 270         rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
 271         dosym /usr/share/fonts/roboto/Roboto-Thin.ttf \
 272                 usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
 273
 274         python_domodule tools/EventClients/lib/python/xbmcclient.py
 275         python_newscript "tools/EventClients/Clients/Kodi Send/kodi-send.py" kodi-send
 276 }