media-tv/dvbstream/dvbstream-0.7_pre20080516-r1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 inherit toolchain-funcs
   8
   9 DESCRIPTION="RTP multicast stream server and other tools for DVB cards"
  10 HOMEPAGE="https://sourceforge.net/projects/dvbtools"
  11 MY_P="${PN}-snapshot-20080302"
  12 SRC_URI="mirror://gentoo/${MY_P}.tar.bz2"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17 IUSE=""
  18
  19 RDEPEND="dev-lang/perl"
  20 DEPEND="virtual/linuxtv-dvb-headers"
  21
  22 S="${WORKDIR}/${PN}"
  23
  24 PATCHES=(
  25         "${FILESDIR}/${P}-update.diff"
  26         "${FILESDIR}/${PN}-0.7_pre20080302-telnet-port-switch.diff"
  27 )
  28
  29 src_prepare() {
  30         default
  31
  32         sed -i Makefile \
  33                 -e 's:$(CFLAGS):$(CFLAGS) $(CPPFLAGS):' \
  34                 -e '/CFLAGS.*=.*-g -Wall -O2/s:-g -Wall -O2::' \
  35                 -e '/CFLAGS.*=/s:CFLAGS:CPPFLAGS:' \
  36                 -e 's:-I \.\./DVB/include:-I /usr/include:' \
  37                 -e 's:$(CC):$(CC) $(LDFLAGS):g' \
  38                 || die 'failed to fix flags in the Makefile'
  39
  40         sed -e 's:\./svdrpsend.pl:dvbstream-send.pl:' \
  41                 -i TELNET/*.sh \
  42                 || die 'failed to rename the svdrpsend.pl command in scripts'
  43
  44         sed -e 's:^DUMPRTP=.*$:DUMPRTP=dumprtp:' \
  45                 -e 's:^TS2ES=.*$:TS2ES=ts2es:' \
  46                 -i *.sh \
  47                 || die 'failed to set DUMPRTP and TS2ES in scripts'
  48 }
  49
  50 src_compile() {
  51         emake CC="$(tc-getCC)" LDFLAGS="${LDFLAGS}"
  52 }
  53
  54 src_install() {
  55         dobin dvbstream dumprtp rtpfeed ts_filter
  56         newbin TELNET/svdrpsend.pl dvbstream-send.pl
  57
  58         dodoc README*
  59         newdoc TELNET/README README.telnet
  60
  61         insinto "/usr/share/doc/${PF}/tune"
  62         doins TELNET/*.sh
  63
  64         insinto "/usr/share/doc/${PF}/multicast"
  65         doins *.sh
  66 }