media-sound/whipper/whipper-0.9.0.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7} )
   7
   8 inherit distutils-r1
   9
  10 DESCRIPTION="A Python CD-DA ripper preferring accuracy over speed (forked from morituri)"
  11 HOMEPAGE="https://github.com/whipper-team/whipper"
  12 SRC_URI="https://github.com/whipper-team/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  13
  14 LICENSE="GPL-3+"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17
  18 DEPEND="media-libs/libsndfile:="
  19 RDEPEND="
  20         ${DEPEND}
  21         app-cdr/cdrdao
  22         >=dev-libs/libcdio-paranoia-0.94_p2
  23         >=dev-python/pycdio-2.1.0[${PYTHON_USEDEP}]
  24         dev-python/pygobject:3[${PYTHON_USEDEP}]
  25         dev-python/python-musicbrainz-ngs[${PYTHON_USEDEP}]
  26         dev-python/requests[${PYTHON_USEDEP}]
  27         dev-python/ruamel-yaml[${PYTHON_USEDEP}]
  28         dev-python/setuptools[${PYTHON_USEDEP}]
  29         media-libs/mutagen[${PYTHON_USEDEP}]
  30         media-sound/sox[flac]"
  31 BDEPEND="
  32         dev-python/setuptools_scm[${PYTHON_USEDEP}]
  33         test? ( dev-python/twisted[${PYTHON_USEDEP}] )"
  34
  35 distutils_enable_tests unittest
  36
  37 PATCHES=( "${FILESDIR}/${PN}-0.7.0-cdparanoia-name-fix.patch" )
  38
  39 python_prepare_all() {
  40         # accurip test totally depends on network access
  41         rm "${PN}"/test/test_common_accurip.py || die
  42
  43         export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
  44
  45         distutils-r1_python_prepare_all
  46 }