media-sound/vorbis-tools/vorbis-tools-1.4.0-r5.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit autotools
   7
   8 DESCRIPTION="Tools for using the Ogg Vorbis sound file format"
   9 HOMEPAGE="http://www.vorbis.com"
  10 SRC_URI="http://downloads.xiph.org/releases/vorbis/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm ~hppa ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
  15 IUSE="flac kate nls +ogg123 speex"
  16
  17 RDEPEND="
  18         >=media-libs/libvorbis-1.3.0
  19         flac? ( media-libs/flac )
  20         kate? ( media-libs/libkate )
  21         ogg123? (
  22                 >=media-libs/libao-1.0.0
  23                 net-misc/curl
  24         )
  25         speex? ( media-libs/speex )
  26 "
  27 DEPEND="${RDEPEND}
  28         virtual/pkgconfig
  29         nls? ( sys-devel/gettext )
  30 "
  31
  32 PATCHES=(
  33         "${FILESDIR}"/${P}-underlinking.patch
  34         "${FILESDIR}"/${P}-format-security.patch
  35         "${FILESDIR}"/${P}-CVE-2014-9640.patch
  36         "${FILESDIR}"/${P}-CVE-2014-9638.patch
  37         "${FILESDIR}"/${P}-docdir.patch
  38 )
  39
  40 src_prepare() {
  41         default
  42         sed -i -e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' configure.ac || die #515220
  43         eautoreconf
  44 }
  45
  46 src_configure() {
  47         econf \
  48                 $(use_enable nls) \
  49                 $(use_enable ogg123) \
  50                 $(use_with flac) \
  51                 $(use_with speex) \
  52                 $(use_with kate)
  53 }