media-sound/tomahawk/tomahawk-0.9.0_pre20181030.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 COMMIT=777b31219179b43f56c7b95857d2fbd7f33199aa
   7 inherit cmake xdg-utils
   8
   9 DESCRIPTION="Multi-source social music player"
  10 HOMEPAGE="https://github.com/tomahawk-player/tomahawk"
  11 SRC_URI="https://github.com/${PN}-player/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
  12
  13 LICENSE="GPL-3 BSD"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="telepathy xmpp"
  17
  18 BDEPEND="
  19         dev-qt/linguist-tools:5
  20 "
  21 COMMON_DEPEND="
  22         dev-qt/qtcore:5
  23         dev-qt/qtdbus:5
  24         dev-qt/qtgui:5
  25         dev-qt/qtnetwork:5
  26         dev-qt/qtsql:5
  27         dev-qt/qtsvg:5
  28         dev-qt/qtwebkit:5
  29         dev-qt/qtwidgets:5
  30         dev-qt/qtx11extras:5
  31         dev-qt/qtxml:5
  32         app-crypt/qca:2[qt5(+)]
  33         dev-cpp/lucene++
  34         dev-cpp/sparsehash
  35         dev-libs/boost:=
  36         dev-libs/qtkeychain:=[qt5(+)]
  37         >=dev-libs/quazip-0.7.2[qt5(+)]
  38         kde-frameworks/extra-cmake-modules:5
  39         kde-frameworks/attica:5
  40         >=media-libs/liblastfm-1.1.0_pre20150206
  41         >=media-libs/taglib-1.8.0
  42         media-video/vlc:=[flac,dvbpsi,ffmpeg,mp3]
  43         >=net-libs/gnutls-3.2:=
  44         x11-libs/libX11
  45         telepathy? ( >=net-libs/telepathy-qt-0.9.7-r1[qt5(+)] )
  46         xmpp? ( >=net-libs/jreen-1.3.0[qt5(+)] )
  47 "
  48 DEPEND="${COMMON_DEPEND}
  49         dev-qt/designer:5
  50         dev-qt/qtconcurrent:5
  51 "
  52 RDEPEND="${COMMON_DEPEND}
  53         app-crypt/qca:2[ssl]
  54 "
  55
  56 S="${WORKDIR}/${PN}-${COMMIT}"
  57
  58 PATCHES=(
  59         "${FILESDIR}/${P}-fix-warning.patch"
  60         "${FILESDIR}/${P}-cmakepolicy.patch" # bug 674826
  61         "${FILESDIR}/${P}-qt-5.15.patch" # pending upstream
  62 )
  63
  64 src_configure() {
  65         local mycmakeargs=(
  66                 -DWITH_CRASHREPORTER=OFF
  67                 -DBUILD_TESTS=OFF
  68                 -DBUILD_TOOLS=OFF
  69                 -DBUILD_HATCHET=OFF
  70                 -DWITH_TelepathyQt=$(usex telepathy)
  71                 -DWITH_Jreen=$(usex xmpp)
  72         )
  73
  74         [[ ${PV} != *9999* ]] && mycmakeargs+=( -DBUILD_RELEASE=ON )
  75
  76         cmake_src_configure
  77 }
  78
  79 pkg_postinst() {
  80         xdg_desktop_database_update
  81 }
  82
  83 pkg_postrm() {
  84         xdg_desktop_database_update
  85 }