media-sound/terminatorx/terminatorx-3.84-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 GCONF_DEBUG="no"
   6
   7 inherit gnome2 eutils
   8
   9 MY_P=${P/terminatorx/terminatorX}
  10
  11 DESCRIPTION="Realtime audio synthesizer allowing you to 'scratch' on sampled audio data"
  12 HOMEPAGE="http://www.terminatorx.org/"
  13 SRC_URI="http://www.terminatorx.org/dist/${MY_P}.tar.gz"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="amd64 x86"
  18 IUSE="alsa debug mad vorbis sox"
  19
  20 RDEPEND="
  21         alsa? ( media-libs/alsa-lib )
  22         mad? ( media-sound/madplay )
  23         vorbis? ( media-libs/libvorbis )
  24         sox? ( media-sound/sox
  25                 media-sound/mpg123 )
  26         >=x11-libs/gtk+-2.2:2
  27         >=dev-libs/glib-2.2:2
  28         x11-libs/libXi
  29         x11-libs/libXxf86dga
  30         dev-libs/libxml2
  31         media-libs/audiofile
  32         media-libs/ladspa-sdk
  33         media-libs/ladspa-cmt
  34         app-text/scrollkeeper
  35         media-libs/liblrdf
  36 "
  37 DEPEND="${RDEPEND}
  38         virtual/pkgconfig
  39         x11-proto/xproto
  40         x11-proto/inputproto
  41         x11-proto/xf86dgaproto
  42 "
  43
  44 S=${WORKDIR}/${MY_P}
  45
  46 src_prepare() {
  47         # Patch from debian to compile with recent zlib
  48         epatch "${FILESDIR}"/${PN}-3.84-new-zlib.patch
  49         epatch "${FILESDIR}"/${PN}-3.84-includes.patch
  50         gnome2_src_prepare
  51 }
  52
  53 src_configure() {
  54         gnome2_src_configure \
  55                 $(use_enable alsa) \
  56                 $(use_enable debug) \
  57                 $(use_enable mad) \
  58                 $(use_enable vorbis) \
  59                 $(use_enable sox)
  60 }
  61
  62 src_install() {
  63         gnome2_src_install
  64         newicon gnome-support/terminatorX-app.png terminatorX.png
  65         make_desktop_entry terminatorX terminatorX terminatorX AudioVideo
  66 }