media-sound/teamspeak-client/teamspeak-client-3.3.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit desktop toolchain-funcs unpacker xdg-utils
   7
   8 MY_PV="${PV/_/-}"
   9
  10 DESCRIPTION="A client software for quality voice communication via the internet"
  11 HOMEPAGE="https://www.teamspeak.com/"
  12 SRC_URI="
  13         amd64? ( https://files.teamspeak-services.com/releases/client/${PV}/TeamSpeak3-Client-linux_amd64-${MY_PV}.run )
  14         x86? ( https://files.teamspeak-services.com/releases/client/${PV}/TeamSpeak3-Client-linux_x86-${MY_PV}.run )
  15 "
  16
  17 KEYWORDS="-* ~amd64 ~x86"
  18 LICENSE="teamspeak3 || ( GPL-2 GPL-3 LGPL-3 )"
  19 SLOT="0"
  20 IUSE="alsa pulseaudio"
  21 REQUIRED_USE="|| ( alsa pulseaudio )"
  22
  23 RDEPEND="
  24         app-arch/snappy:0/1
  25         dev-libs/openssl:0
  26         dev-libs/quazip
  27         dev-qt/qtcore:5
  28         dev-qt/qtgui:5[accessibility,dbus,xcb]
  29         dev-qt/qtnetwork:5
  30         dev-qt/qtsql:5[sqlite]
  31         dev-qt/qtsvg:5
  32         dev-qt/qtwebchannel:5
  33         dev-qt/qtwebengine:5[geolocation(+),widgets]
  34         dev-qt/qtwidgets:5
  35         net-libs/libsrtp:0
  36         sys-libs/libcxx[libcxxabi]
  37         sys-libs/zlib:0/1
  38         virtual/udev
  39         alsa? ( media-libs/alsa-lib )
  40         pulseaudio? ( media-sound/pulseaudio )
  41 "
  42
  43 RESTRICT="bindist mirror"
  44
  45 S="${WORKDIR}"
  46
  47 QA_PREBUILT="
  48         opt/teamspeak3-client/error_report
  49         opt/teamspeak3-client/package_inst
  50         opt/teamspeak3-client/soundbackends/libalsa_linux_*.so
  51         opt/teamspeak3-client/soundbackends/libpulseaudio_linux_*.so
  52         opt/teamspeak3-client/ts3client
  53         opt/teamspeak3-client/update
  54 "
  55
  56 src_prepare() {
  57         default
  58
  59         if ! use alsa; then
  60                 rm -f soundbackends/libalsa_linux_*.so || die
  61         fi
  62
  63         if ! use pulseaudio ; then
  64                 rm -f soundbackends/libpulseaudio_linux_*.so || die
  65         fi
  66
  67         mv ts3client_linux_* ts3client || die
  68
  69         tc-export CXX
  70 }
  71
  72 src_install() {
  73         exeinto /opt/teamspeak3-client
  74         doexe error_report package_inst ts3client update
  75         newexe "${FILESDIR}"/ts3client-bin-r2 ts3client-bin
  76
  77         exeinto /opt/teamspeak3-client/soundbackends
  78         doexe soundbackends/*.so
  79
  80         insinto /opt/teamspeak3-client
  81         doins -r gfx html resources sound styles translations
  82
  83         dosym ../../usr/$(get_libdir)/qt5/libexec/QtWebEngineProcess /opt/teamspeak3-client/QtWebEngineProcess
  84
  85         dodir /opt/bin
  86         dosym ../teamspeak3-client/ts3client-bin /opt/bin/ts3client
  87
  88         make_desktop_entry /opt/bin/ts3client "Teamspeak 3 Client" /opt/teamspeak3-client/styles/default/logo-128x128.png "Audio;AudioVideo;Network"
  89
  90         einstalldocs
  91 }
  92
  93 pkg_postinst() {
  94         xdg_desktop_database_update
  95         xdg_mimeinfo_database_update
  96 }
  97
  98 pkg_postrm() {
  99         xdg_desktop_database_update
 100         xdg_mimeinfo_database_update
 101 }