media-sound/teamspeak-client/teamspeak-client-3.2.3-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit desktop unpacker xdg-utils
   7
   8 MY_PV="${PV/_/-}"
   9
  10 DESCRIPTION="A client software for quality voice communication via the internet"
  11 HOMEPAGE="https://www.teamspeak.com/"
  12 SRC_URI="amd64? ( http://ftp.4players.de/pub/hosted/ts3/releases/${PV}/TeamSpeak3-Client-linux_amd64-${MY_PV}.run )
  13         x86? ( http://ftp.4players.de/pub/hosted/ts3/releases/${PV}/TeamSpeak3-Client-linux_x86-${MY_PV}.run )"
  14
  15 KEYWORDS="-* ~amd64 ~x86"
  16 LICENSE="teamspeak3"
  17 SLOT="0"
  18 IUSE="alsa pulseaudio"
  19 REQUIRED_USE="|| ( alsa pulseaudio )"
  20
  21 RDEPEND="
  22         app-arch/snappy:0/1
  23         =dev-libs/openssl-1.0*:*
  24         dev-libs/quazip
  25         <dev-qt/qtcore-5.12.0:5
  26         <dev-qt/qtgui-5.12.0:5[accessibility,dbus,xcb]
  27         <dev-qt/qtnetwork-5.12.0:5
  28         <dev-qt/qtsql-5.12.0:5[sqlite]
  29         <dev-qt/qtsvg-5.12.0:5
  30         <dev-qt/qtwebchannel-5.12.0:5
  31         <dev-qt/qtwebengine-5.12.0:5[geolocation,widgets]
  32         <dev-qt/qtwidgets-5.12.0:5
  33         net-libs/libsrtp:0
  34         sys-libs/libcxx[libcxxabi]
  35         sys-libs/zlib:0/1
  36         virtual/udev
  37         alsa? ( media-libs/alsa-lib )
  38         pulseaudio? ( media-sound/pulseaudio )
  39 "
  40
  41 RESTRICT="mirror"
  42
  43 S="${WORKDIR}"
  44
  45 QA_PREBUILT="
  46         opt/teamspeak3-client/error_report
  47         opt/teamspeak3-client/package_inst
  48         opt/teamspeak3-client/soundbackends/libalsa_linux_*.so
  49         opt/teamspeak3-client/soundbackends/libpulseaudio_linux_*.so
  50         opt/teamspeak3-client/ts3client
  51         opt/teamspeak3-client/update
  52 "
  53
  54 src_prepare() {
  55         default
  56
  57         if ! use alsa; then
  58                 rm -f soundbackends/libalsa_linux_*.so || die
  59         fi
  60         if ! use pulseaudio ; then
  61                 rm -f soundbackends/libpulseaudio_linux_*.so || die
  62         fi
  63
  64         mv ts3client_linux_* ts3client || die
  65 }
  66
  67 src_install() {
  68         exeinto /opt/teamspeak3-client
  69         doexe error_report package_inst ts3client "${FILESDIR}"/ts3client-bin update
  70
  71         exeinto /opt/teamspeak3-client/soundbackends
  72         doexe soundbackends/*.so
  73
  74         insinto /opt/teamspeak3-client
  75         doins -r gfx html resources sound styles translations
  76
  77         dosym ../../usr/$(get_libdir)/qt5/libexec/QtWebEngineProcess /opt/teamspeak3-client/QtWebEngineProcess
  78
  79         dodir /opt/bin
  80         dosym ../teamspeak3-client/ts3client-bin /opt/bin/ts3client
  81
  82         make_desktop_entry /opt/bin/ts3client "Teamspeak 3 Client" /opt/teamspeak3-client/styles/default/logo-128x128.png "Audio;AudioVideo;Network"
  83
  84         einstalldocs
  85 }
  86
  87 pkg_postinst() {
  88         xdg_desktop_database_update
  89         xdg_mimeinfo_database_update
  90 }
  91
  92 pkg_postrm() {
  93         xdg_desktop_database_update
  94         xdg_mimeinfo_database_update
  95 }