media-sound/rplay/rplay-3.3.2-r3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit autotools user
   6
   7 DESCRIPTION="Play sounds on remote Unix systems without data transfer"
   8 HOMEPAGE="http://rplay.doit.org/"
   9 SRC_URI="http://rplay.doit.org/dist/${P}.tar.gz
  10         mirror://debian/pool/main/r/${PN}/${PN}_${PV}-16.debian.tar.xz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm hppa ~ia64 ppc ppc64 s390 sparc x86"
  15 IUSE=""
  16
  17 RDEPEND="media-sound/gsm"
  18 DEPEND="${RDEPEND}"
  19
  20 PATCHES=(
  21         "${WORKDIR}/debian/patches"
  22         "${FILESDIR}/${P}-built-in_function_exit-r1.patch"
  23 )
  24
  25 pkg_setup() {
  26         enewgroup rplayd ""
  27         enewuser rplayd "" "" "" rplayd
  28 }
  29
  30 src_prepare() {
  31         default
  32         mv configure.{in,ac} || die
  33         mv rx/configure.{in,ac} || die
  34         eautoreconf
  35 }
  36
  37 src_configure() {
  38         econf \
  39                 --enable-rplayd-user=rplayd \
  40                 --enable-rplayd-group=rplayd
  41 }
  42
  43 src_install() {
  44         # This is borrowed from the old einstall helper, and is necessary
  45         # (at least some of variables).
  46         emake prefix="${ED}/usr" \
  47                 libdir="${ED}/usr/$(get_libdir)" \
  48                 datadir="${ED}/usr/share" \
  49                 infodir="${ED}/usr/share/info" \
  50                 localstatedir="${ED}/var/lib" \
  51                 mandir="${ED}/usr/share/man" \
  52                 sysconfdir="${ED}/etc" \
  53                 install
  54 }