media-sound/rosegarden/rosegarden-14.02.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 inherit autotools eutils xdg-utils gnome2-utils multilib
   6
   7 DESCRIPTION="MIDI and audio sequencer and notation editor"
   8 HOMEPAGE="http://www.rosegardenmusic.com/"
   9 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~ppc ~x86"
  14 IUSE="debug lirc"
  15
  16 RDEPEND="dev-qt/qtgui:4
  17         media-libs/ladspa-sdk:=
  18         x11-libs/libSM:=
  19         media-sound/jack-audio-connection-kit:=
  20         media-libs/alsa-lib:=
  21         >=media-libs/dssi-1.0.0:=
  22         media-libs/liblo:=
  23         media-libs/liblrdf:=
  24         sci-libs/fftw:3.0
  25         media-libs/libsamplerate:=[sndfile]
  26         lirc? ( app-misc/lirc:= )"
  27 DEPEND="${RDEPEND}
  28         virtual/pkgconfig
  29         x11-misc/makedepend"
  30
  31 src_prepare() {
  32         epatch "${FILESDIR}"/${PN}-12.12.25-debug.patch
  33         eautoreconf
  34 }
  35
  36 src_configure() {
  37         export USER_CXXFLAGS="${CXXFLAGS}"
  38
  39         export ac_cv_header_lirc_lirc_client_h=$(usex lirc)
  40         export ac_cv_lib_lirc_client_lirc_init=$(usex lirc)
  41
  42         econf \
  43                 $(use_enable debug) \
  44                 --with-qtdir=/usr \
  45                 --with-qtlibdir=/usr/$(get_libdir)/qt4
  46 }
  47
  48 pkg_preinst() {
  49         gnome2_icon_savelist
  50 }
  51
  52 pkg_postinst() {
  53         gnome2_icon_cache_update
  54         xdg_desktop_database_update
  55         xdg_mimeinfo_database_update
  56 }
  57
  58 pkg_postrm() {
  59         gnome2_icon_cache_update
  60         xdg_desktop_database_update
  61         xdg_mimeinfo_database_update
  62 }