media-sound/ripperx/ripperx-2.7.3.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 inherit eutils
   6
   7 MY_P=${P/x/X}
   8 MY_PN=${PN/x/X}
   9
  10 DESCRIPTION="a GTK program to rip CD audio tracks and encode them to the Ogg, MP3, or FLAC formats"
  11 HOMEPAGE="https://sourceforge.net/projects/ripperx"
  12 SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="amd64 ppc x86"
  17 IUSE="nls"
  18
  19 RDEPEND="media-libs/id3lib
  20         media-sound/cdparanoia
  21         media-sound/lame
  22         x11-libs/gtk+:2"
  23 DEPEND="${RDEPEND}
  24         virtual/pkgconfig
  25         nls? ( sys-devel/gettext )"
  26
  27 S=${WORKDIR}/${MY_P}
  28
  29 src_prepare() {
  30         # AC_CHECK_LIB(m, ceilf, [], [MATH_LIB="-lm" MATH_LIB=""]) #401867
  31         sed -i -e '/ripperX_LDADD/s:=:= -lm:' src/Makefile.in || die
  32
  33         epatch \
  34                 "${FILESDIR}"/${P}-ldflags.patch \
  35                 "${FILESDIR}"/${P}-pkgconfig.patch
  36 }
  37
  38 src_configure() {
  39         econf $(use_enable nls)
  40 }
  41
  42 src_install() {
  43         emake DESTDIR="${D}" install
  44         dodoc BUGS CHANGES FAQ README* TODO
  45         doicon src/xpms/${MY_PN}-icon.xpm
  46         make_desktop_entry ${MY_PN} ${MY_PN} ${MY_PN}-icon
  47 }