media-sound/rhythmbox/rhythmbox-3.4.4.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GNOME2_LA_PUNT="yes"
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7 PYTHON_REQ_USE="xml"
   8
   9 inherit eutils gnome2 python-single-r1 multilib virtualx
  10
  11 DESCRIPTION="Music management and playback software for GNOME"
  12 HOMEPAGE="https://wiki.gnome.org/Apps/Rhythmbox"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16
  17 IUSE="cdr daap dbus gnome-keyring ipod libnotify lirc mtp +python test +udev upnp-av"
  18 RESTRICT="!test? ( test )"
  19 REQUIRED_USE="
  20         ipod? ( udev )
  21         mtp? ( udev )
  22         dbus? ( python )
  23         python? ( ${PYTHON_REQUIRED_USE} )
  24 "
  25
  26 KEYWORDS="~alpha amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc x86"
  27
  28 COMMON_DEPEND="
  29         >=dev-libs/glib-2.38:2
  30         >=dev-libs/libxml2-2.7.8:2
  31         >=x11-libs/gtk+-3.20.0:3[X,introspection]
  32         >=x11-libs/gdk-pixbuf-2.18:2
  33         >=dev-libs/gobject-introspection-0.10:=
  34         >=dev-libs/libpeas-0.7.3[gtk]
  35         >=dev-libs/totem-pl-parser-3.2
  36         >=net-libs/libsoup-2.42:2.4
  37         >=media-libs/gst-plugins-base-1.4:1.0[introspection]
  38         >=media-libs/gstreamer-1.4:1.0[introspection]
  39         >=sys-libs/tdb-1.2.6
  40         dev-libs/json-glib
  41
  42         cdr? ( >=app-cdr/brasero-2.91.90 )
  43         daap? (
  44                 >=net-libs/libdmapsharing-2.9.19:3.0
  45                 >=media-plugins/gst-plugins-soup-1.4:1.0 )
  46         gnome-keyring? ( >=app-crypt/libsecret-0.18 )
  47         libnotify? ( >=x11-libs/libnotify-0.7.0 )
  48         lirc? ( app-misc/lirc )
  49         python? (
  50                 ${PYTHON_DEPS}
  51                 $(python_gen_cond_dep '
  52                         >=dev-python/pygobject-3.0:3[${PYTHON_MULTI_USEDEP}]
  53                 ')
  54         )
  55         udev? (
  56                 dev-libs/libgudev:=
  57                 ipod? ( >=media-libs/libgpod-0.7.92[udev] )
  58                 mtp? ( >=media-libs/libmtp-0.3 ) )
  59 "
  60 RDEPEND="${COMMON_DEPEND}
  61         media-plugins/gst-plugins-soup:1.0
  62         media-plugins/gst-plugins-libmms:1.0
  63         || (
  64                 media-plugins/gst-plugins-cdparanoia:1.0
  65                 media-plugins/gst-plugins-cdio:1.0 )
  66         media-plugins/gst-plugins-meta:1.0
  67         media-plugins/gst-plugins-taglib:1.0
  68         x11-themes/adwaita-icon-theme
  69         python? (
  70                 >=dev-libs/libpeas-0.7.3[python,${PYTHON_SINGLE_USEDEP}]
  71                 net-libs/libsoup:2.4[introspection]
  72                 x11-libs/gdk-pixbuf:2[introspection]
  73                 x11-libs/gtk+:3[introspection]
  74                 x11-libs/pango[introspection]
  75
  76                 dbus? ( sys-apps/dbus )
  77                 gnome-keyring? ( >=app-crypt/libsecret-0.18[introspection] ) )
  78         upnp-av? (
  79                 >=media-libs/grilo-0.3:0.3
  80                 >=media-plugins/grilo-plugins-0.3:0.3[upnp-av] )
  81 "
  82 DEPEND="${COMMON_DEPEND}
  83         dev-util/gtk-doc-am
  84         >=dev-util/intltool-0.35
  85         dev-util/itstool
  86         virtual/pkgconfig
  87         test? ( dev-libs/check )
  88 "
  89 # eautoreconf needs yelp-tools
  90
  91 pkg_setup() {
  92         use python && python-single-r1_pkg_setup
  93 }
  94
  95 src_configure() {
  96         # --enable-vala just installs the sample vala plugin, and the configure
  97         # checks are broken, so don't enable it
  98         gnome2_src_configure \
  99                 VALAC=$(type -P true) \
 100                 --enable-mmkeys \
 101                 --disable-more-warnings \
 102                 --disable-static \
 103                 --disable-vala \
 104                 $(use_enable daap) \
 105                 $(use_enable libnotify) \
 106                 $(use_enable lirc) \
 107                 $(use_enable python) \
 108                 $(use_enable upnp-av grilo) \
 109                 $(use_with cdr brasero) \
 110                 $(use_with gnome-keyring libsecret) \
 111                 $(use_with ipod) \
 112                 $(use_with mtp) \
 113                 $(use_with udev gudev)
 114 }
 115
 116 src_test() {
 117         unset SESSION_MANAGER
 118         "${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
 119         GSETTINGS_SCHEMA_DIR="${S}/data" virtx emake check CK_DEFAULT_TIMEOUT=60
 120 }
 121
 122 src_install() {
 123         DOCS="AUTHORS ChangeLog DOCUMENTERS INTERNALS \
 124                 MAINTAINERS MAINTAINERS.old NEWS README THANKS"
 125
 126         gnome2_src_install
 127 }