media-sound/qtractor/qtractor-0.9.2.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic qmake-utils
   7
   8 DESCRIPTION="Audio/MIDI multi-track sequencer written in C++ with the Qt framework"
   9 HOMEPAGE="https://qtractor.sourceforge.io"
  10 SRC_URI="mirror://sourceforge/qtractor/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15
  16 IUSE="cpu_flags_x86_sse debug dssi libsamplerate mad osc rubberband vorbis zlib"
  17
  18 RDEPEND="
  19         dev-qt/qtcore:5
  20         dev-qt/qtgui:5
  21         dev-qt/qtwidgets:5
  22         dev-qt/qtxml:5
  23         dev-qt/qtx11extras:5
  24         media-libs/alsa-lib
  25         media-libs/ladspa-sdk
  26         media-libs/libsndfile
  27         >=media-libs/lilv-0.16.0
  28         media-libs/lv2
  29         media-libs/suil
  30         virtual/jack
  31         dssi? ( media-libs/dssi )
  32         libsamplerate? ( media-libs/libsamplerate )
  33         mad? ( media-libs/libmad )
  34         osc? ( media-libs/liblo )
  35         rubberband? ( media-libs/rubberband )
  36         vorbis? ( media-libs/libvorbis )
  37         zlib? ( sys-libs/zlib )
  38 "
  39 DEPEND="${RDEPEND}
  40         dev-qt/linguist-tools:5
  41         virtual/pkgconfig
  42 "
  43
  44 src_configure() {
  45         append-cxxflags -std=c++11
  46         econf \
  47                 --enable-ladspa \
  48                 --enable-lilv \
  49                 --disable-qt4 \
  50                 --with-qt5=$(qt5_get_libdir)/qt5 \
  51                 $(use_enable debug) \
  52                 $(use_enable dssi) \
  53                 $(use_enable libsamplerate) \
  54                 $(use_enable mad libmad) \
  55                 $(use_enable osc liblo) \
  56                 $(use_enable rubberband librubberband) \
  57                 $(use_enable cpu_flags_x86_sse sse) \
  58                 $(use_enable vorbis libvorbis) \
  59                 $(use_enable zlib libz)
  60
  61         eqmake5 ${PN}.pro -o ${PN}.mak
  62 }