media-sound/qtractor/qtractor-0.9.13.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic qmake-utils xdg
   7
   8 DESCRIPTION="Audio/MIDI multi-track sequencer written in C++ with the Qt framework"
   9 HOMEPAGE="https://qtractor.sourceforge.io"
  10 SRC_URI="mirror://sourceforge/qtractor/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 x86"
  15
  16 IUSE="aubio cpu_flags_x86_sse debug dssi libsamplerate mad osc rubberband vorbis zlib"
  17
  18 BDEPEND="
  19         dev-qt/linguist-tools:5
  20         virtual/pkgconfig
  21 "
  22 DEPEND="
  23         dev-qt/qtcore:5
  24         dev-qt/qtgui:5
  25         dev-qt/qtwidgets:5
  26         dev-qt/qtxml:5
  27         dev-qt/qtx11extras:5
  28         media-libs/alsa-lib
  29         media-libs/ladspa-sdk
  30         media-libs/libsndfile
  31         >=media-libs/lilv-0.16.0
  32         media-libs/lv2
  33         media-libs/suil
  34         virtual/jack
  35         aubio? ( media-libs/aubio )
  36         dssi? ( media-libs/dssi )
  37         libsamplerate? ( media-libs/libsamplerate )
  38         mad? ( media-libs/libmad )
  39         osc? ( media-libs/liblo )
  40         rubberband? ( media-libs/rubberband )
  41         vorbis? ( media-libs/libvorbis )
  42         zlib? ( sys-libs/zlib )
  43 "
  44 RDEPEND="${DEPEND}"
  45
  46 PATCHES=(
  47         "${FILESDIR}/${P}-dont-compress-manpages.patch"
  48 )
  49
  50 src_configure() {
  51         append-cxxflags -std=c++11
  52         econf \
  53                 --enable-ladspa \
  54                 --enable-liblilv \
  55                 $(use_enable debug) \
  56                 $(use_enable aubio libaubio) \
  57                 $(use_enable dssi) \
  58                 $(use_enable libsamplerate) \
  59                 $(use_enable mad libmad) \
  60                 $(use_enable osc liblo) \
  61                 $(use_enable rubberband librubberband) \
  62                 $(use_enable cpu_flags_x86_sse sse) \
  63                 $(use_enable vorbis libvorbis) \
  64                 $(use_enable zlib libz)
  65
  66         eqmake5 ${PN}.pro -o ${PN}.mak
  67 }