media-sound/qmmp/qmmp-1.3.7.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cmake xdg-utils
   7 [[ ${PV} = 9999 ]] && inherit subversion
   8
   9 DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
  10 HOMEPAGE="http://qmmp.ylsoftware.com"
  11 if [[ ${PV} != 9999 ]]; then
  12         SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2
  13                 mirror://sourceforge/${PN}-dev/files/${P}.tar.bz2"
  14         KEYWORDS="~amd64 ~x86"
  15 else
  16         QMMP_DEV_BRANCH="1.3"
  17         ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
  18 fi
  19
  20 LICENSE="GPL-2"
  21 SLOT="0"
  22 # KEYWORDS further up
  23 IUSE="aac +alsa analyzer archive bs2b cdda cover crossfade cue curl +dbus enca ffmpeg flac game
  24 gnome jack ladspa lyrics +mad midi mms modplug mplayer musepack notifier opus oss projectm
  25 pulseaudio qsui qtmedia scrobbler shout sid sndfile soxr stereo tray udisks +vorbis wavpack"
  26
  27 REQUIRED_USE="
  28         gnome? ( dbus )
  29         shout? ( soxr vorbis )
  30         udisks? ( dbus )
  31 "
  32
  33 RDEPEND="
  34         dev-qt/qtcore:5
  35         dev-qt/qtgui:5
  36         dev-qt/qtnetwork:5
  37         dev-qt/qtsql:5
  38         dev-qt/qtwidgets:5
  39         dev-qt/qtx11extras:5
  40         media-libs/taglib
  41         x11-libs/libX11
  42         aac? ( media-libs/faad2 )
  43         alsa? ( media-libs/alsa-lib )
  44         archive? ( app-arch/libarchive )
  45         bs2b? ( media-libs/libbs2b )
  46         cdda? (
  47                 dev-libs/libcdio:=
  48                 dev-libs/libcdio-paranoia
  49         )
  50         curl? ( net-misc/curl )
  51         dbus? ( dev-qt/qtdbus:5 )
  52         enca? ( app-i18n/enca )
  53         ffmpeg? ( media-video/ffmpeg:= )
  54         flac? ( media-libs/flac )
  55         game? ( media-libs/game-music-emu )
  56         jack? (
  57                 media-libs/libsamplerate
  58                 media-sound/jack-audio-connection-kit
  59         )
  60         ladspa? ( media-libs/ladspa-cmt )
  61         mad? ( || (
  62                 media-libs/libmad
  63                 media-sound/mpg123
  64         ) )
  65         midi? ( media-sound/wildmidi )
  66         mms? ( media-libs/libmms )
  67         modplug? ( >=media-libs/libmodplug-0.8.4 )
  68         mplayer? ( media-video/mplayer )
  69         musepack? ( >=media-sound/musepack-tools-444 )
  70         opus? ( media-libs/opusfile )
  71         projectm? (
  72                 dev-qt/qtgui:5[-gles2-only]
  73                 dev-qt/qtopengl:5
  74                 media-libs/libprojectm:=
  75         )
  76         pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
  77         qtmedia? ( dev-qt/qtmultimedia:5 )
  78         scrobbler? ( net-misc/curl )
  79         shout? ( media-libs/libshout )
  80         sid? ( >=media-libs/libsidplayfp-1.1.0 )
  81         sndfile? ( media-libs/libsndfile )
  82         soxr? ( media-libs/soxr )
  83         udisks? ( sys-fs/udisks:2 )
  84         vorbis? (
  85                 media-libs/libogg
  86                 media-libs/libvorbis
  87         )
  88         wavpack? ( media-sound/wavpack )
  89 "
  90 DEPEND="${RDEPEND}
  91         dev-qt/linguist-tools:5
  92 "
  93
  94 DOCS=( AUTHORS ChangeLog README )
  95
  96 src_prepare() {
  97         if has_version dev-libs/libcdio-paranoia; then
  98                 sed -i \
  99                         -e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
 100                         src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
 101         fi
 102
 103         cmake_src_prepare
 104 }
 105
 106 src_configure() {
 107         local mycmakeargs=(
 108                 -DUSE_AAC="$(usex aac)"
 109                 -DUSE_ALSA="$(usex alsa)"
 110                 -DUSE_ANALYZER="$(usex analyzer)"
 111                 -DUSE_ARCHIVE="$(usex archive)"
 112                 -DUSE_BS2B="$(usex bs2b)"
 113                 -DUSE_CDA="$(usex cdda)"
 114                 -DUSE_COVER="$(usex cover)"
 115                 -DUSE_CROSSFADE="$(usex crossfade)"
 116                 -DUSE_CUE="$(usex cue)"
 117                 -DUSE_CURL="$(usex curl)"
 118                 -DUSE_KDENOTIFY="$(usex dbus)"
 119                 -DUSE_MPRIS="$(usex dbus)"
 120                 -DUSE_ENCA="$(usex enca)"
 121                 -DUSE_FFMPEG="$(usex ffmpeg)"
 122                 -DUSE_FILEWRITER="$(usex vorbis)"
 123                 -DUSE_FLAC="$(usex flac)"
 124                 -DUSE_GME="$(usex game)"
 125                 -DUSE_GNOMEHOTKEY="$(usex gnome)"
 126                 -DUSE_HAL=OFF
 127                 -DUSE_JACK="$(usex jack)"
 128                 -DUSE_LADSPA="$(usex ladspa)"
 129                 -DUSE_LYRICS="$(usex lyrics)"
 130                 -DUSE_MAD="$(usex mad)"
 131                 -DUSE_MIDI="$(usex midi)"
 132                 -DUSE_MMS="$(usex mms)"
 133                 -DUSE_MODPLUG="$(usex modplug)"
 134                 -DUSE_MPLAYER="$(usex mplayer)"
 135                 -DUSE_MPC="$(usex musepack)"
 136                 -DUSE_NOTIFIER="$(usex notifier)"
 137                 -DUSE_OPUS="$(usex opus)"
 138                 -DUSE_OSS="$(usex oss)"
 139                 -DUSE_PROJECTM="$(usex projectm)"
 140                 -DUSE_PULSE="$(usex pulseaudio)"
 141                 -DUSE_QSUI="$(usex qsui)"
 142                 -DUSE_QTMULTIMEDIA="$(usex qtmedia)"
 143                 -DUSE_SCROBBLER="$(usex scrobbler)"
 144                 -DUSE_SHOUT="$(usex shout)"
 145                 -DUSE_SID="$(usex sid)"
 146                 -DUSE_SNDFILE="$(usex sndfile)"
 147                 -DUSE_SOXR="$(usex soxr)"
 148                 -DUSE_STEREO="$(usex stereo)"
 149                 -DUSE_STATICON="$(usex tray)"
 150                 -DUSE_UDISKS2="$(usex udisks)"
 151                 -DUSE_VORBIS="$(usex vorbis)"
 152                 -DUSE_WAVPACK="$(usex wavpack)"
 153         )
 154
 155         cmake_src_configure
 156 }
 157
 158 pkg_postinst() {
 159         xdg_desktop_database_update
 160 }
 161
 162 pkg_postrm() {
 163         xdg_desktop_database_update
 164 }