media-sound/qmmp/qmmp-1.0.6.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 inherit cmake-utils
   8 [ "$PV" == "9999" ] && inherit subversion
   9
  10 DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
  11 HOMEPAGE="http://qmmp.ylsoftware.com"
  12 if [ "$PV" != "9999" ]; then
  13         SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2"
  14         KEYWORDS="~amd64 ~x86"
  15 else
  16         QMMP_DEV_BRANCH="1.1"
  17         SRC_URI=""
  18         ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
  19         KEYWORDS=""
  20 fi
  21
  22 LICENSE="GPL-2"
  23 SLOT="0"
  24 # KEYWORDS further up
  25 IUSE="analyzer aac +alsa +dbus bs2b cdda cover crossfade cue curl enca ffmpeg flac jack game kde ladspa
  26 libsamplerate lyrics +mad midi mms modplug mplayer mpris musepack notifier opus oss
  27 projectm pulseaudio qsui scrobbler sndfile stereo tray udisks +vorbis wavpack"
  28
  29 RDEPEND="media-libs/taglib
  30         dev-qt/qtcore:5
  31         dev-qt/qtdbus:5
  32         dev-qt/qtgui:5
  33         dev-qt/qtnetwork:5
  34         dev-qt/qtwidgets:5
  35         dev-qt/qtx11extras:5
  36         alsa? ( media-libs/alsa-lib )
  37         bs2b? ( media-libs/libbs2b )
  38         cdda? ( dev-libs/libcdio-paranoia )
  39         cue? ( media-libs/libcue )
  40         curl? ( net-misc/curl )
  41         dbus? ( sys-apps/dbus )
  42         aac? ( media-libs/faad2 )
  43         enca? ( app-i18n/enca )
  44         flac? ( media-libs/flac )
  45         game? ( media-libs/game-music-emu )
  46         ladspa? ( media-libs/ladspa-cmt )
  47         libsamplerate? ( media-libs/libsamplerate )
  48         mad? ( media-libs/libmad )
  49         midi? ( media-sound/wildmidi )
  50         mms? ( media-libs/libmms )
  51         mplayer? ( media-video/mplayer )
  52         mpris? ( dev-qt/qtdbus:5 )
  53         musepack? ( >=media-sound/musepack-tools-444 )
  54         modplug? ( >=media-libs/libmodplug-0.8.4 )
  55         vorbis? ( media-libs/libvorbis
  56                 media-libs/libogg )
  57         jack? ( media-sound/jack-audio-connection-kit
  58                 media-libs/libsamplerate )
  59         ffmpeg? ( virtual/ffmpeg )
  60         opus? ( media-libs/opusfile )
  61         projectm? ( media-libs/libprojectm
  62                 dev-qt/qtopengl:5
  63                 dev-qt/qtgui:5[-gles2] )
  64         pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
  65         wavpack? ( media-sound/wavpack )
  66         scrobbler? ( net-misc/curl )
  67         sndfile? ( media-libs/libsndfile )
  68         udisks? ( sys-fs/udisks:2 )"
  69 DEPEND="${RDEPEND}
  70         dev-qt/linguist-tools:5"
  71
  72 DOCS="AUTHORS ChangeLog README"
  73
  74 CMAKE_IN_SOURCE_BUILD="1"
  75
  76 REQUIRED_USE="kde? ( dbus ) "
  77
  78 src_prepare() {
  79         if has_version dev-libs/libcdio-paranoia; then
  80                 sed -i \
  81                         -e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
  82                         src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
  83         fi
  84
  85         cmake-utils_src_prepare
  86 }
  87
  88 src_configure() {
  89         mycmakeargs=(
  90                 -DUSE_alsa="$(usex alsa)"
  91                 -DUSE_aac="$(usex aac)"
  92                 -DUSE_analyzer="$(usex analyzer)"
  93                 -DUSE_bs2b="$(usex bs2b)"
  94                 -DUSE_CDA="$(usex cdda)"
  95                 -DUSE_crossfade="$(usex crossfade)"
  96                 -DUSE_cover="$(usex cover)"
  97                 -DUSE_cue="$(usex cue)"
  98                 -DUSE_curl="$(usex curl)"
  99                 -DUSE_dbus="$(usex dbus)"
 100                 -DUSE_enca="$(usex enca)"
 101                 -DUSE_ffmpeg="$(usex ffmpeg)"
 102                 -DUSE_flac="$(usex flac)"
 103                 -DUSE_GME="$(usex game)"
 104                 -DUSE_HAL=OFF
 105                 -DUSE_jack="$(usex jack)"
 106                 -DUSE_KDENOTIFY="$(usex kde)"
 107                 -DUSE_ladspa="$(usex ladspa)"
 108                 -DUSE_lyrics="$(usex lyrics)"
 109                 -DUSE_mad="$(usex mad)"
 110                 -DUSE_MIDI_WILDMIDI="$(usex midi)"
 111                 -DUSE_mplayer="$(usex mplayer)"
 112                 -DUSE_mms="$(usex mms)"
 113                 -DUSE_modplug="$(usex modplug)"
 114                 -DUSE_mpris="$(usex mpris)"
 115                 -DUSE_MPC="$(usex musepack)"
 116                 -DUSE_notifier="$(usex notifier)"
 117                 -DUSE_opus="$(usex opus)"
 118                 -DUSE_oss="$(usex oss)"
 119                 -DUSE_projectm="$(usex projectm)"
 120                 -DUSE_PULSE="$(usex pulseaudio)"
 121                 -DUSE_qsui="$(usex qsui)"
 122                 -DUSE_scrobbler="$(usex scrobbler)"
 123                 -DUSE_sndfile="$(usex sndfile)"
 124                 -DUSE_stereo="$(usex stereo)"
 125                 -DUSE_STATICON="$(usex tray)"
 126                 -DUSE_UDISKS2="$(usex udisks)"
 127                 -DUSE_SRC="$(usex libsamplerate)"
 128                 -DUSE_vorbis="$(usex vorbis)"
 129                 -DUSE_wavpack="$(usex wavpack)"
 130         )
 131
 132         cmake-utils_src_configure
 133 }