media-sound/qmmp/qmmp-1.0.6-r1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 inherit cmake-utils
   8 [ "$PV" == "9999" ] && inherit subversion
   9
  10 DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
  11 HOMEPAGE="http://qmmp.ylsoftware.com"
  12 if [ "$PV" != "9999" ]; then
  13         SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2"
  14         KEYWORDS="~amd64 ~x86"
  15 else
  16         QMMP_DEV_BRANCH="1.1"
  17         SRC_URI=""
  18         ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
  19         KEYWORDS=""
  20 fi
  21
  22 LICENSE="GPL-2"
  23 SLOT="0"
  24 # KEYWORDS further up
  25 IUSE="analyzer aac +alsa +dbus bs2b cdda cover crossfade cue curl enca ffmpeg flac jack game kde ladspa
  26 libsamplerate lyrics +mad midi mms modplug mplayer mpris musepack notifier opus oss
  27 projectm pulseaudio qsui scrobbler sndfile stereo tray udisks +vorbis wavpack"
  28
  29 RDEPEND="media-libs/taglib
  30         dev-qt/qdbusviewer:5
  31         dev-qt/qtcore:5
  32         dev-qt/qtdbus:5
  33         dev-qt/qtgui:5
  34         dev-qt/qtnetwork:5
  35         dev-qt/qtwidgets:5
  36         dev-qt/qtx11extras:5
  37         alsa? ( media-libs/alsa-lib )
  38         bs2b? ( media-libs/libbs2b )
  39         cdda? ( dev-libs/libcdio-paranoia )
  40         cue? ( media-libs/libcue )
  41         curl? ( net-misc/curl )
  42         dbus? ( sys-apps/dbus )
  43         aac? ( media-libs/faad2 )
  44         enca? ( app-i18n/enca )
  45         flac? ( media-libs/flac )
  46         game? ( media-libs/game-music-emu )
  47         ladspa? ( media-libs/ladspa-cmt )
  48         libsamplerate? ( media-libs/libsamplerate )
  49         mad? ( media-libs/libmad )
  50         midi? ( media-sound/wildmidi )
  51         mms? ( media-libs/libmms )
  52         mplayer? ( media-video/mplayer )
  53         mpris? ( dev-qt/qtdbus:5 )
  54         musepack? ( >=media-sound/musepack-tools-444 )
  55         modplug? ( >=media-libs/libmodplug-0.8.4 )
  56         vorbis? ( media-libs/libvorbis
  57                 media-libs/libogg )
  58         jack? ( media-sound/jack-audio-connection-kit
  59                 media-libs/libsamplerate )
  60         ffmpeg? ( virtual/ffmpeg )
  61         opus? ( media-libs/opusfile )
  62         projectm? ( media-libs/libprojectm
  63                 dev-qt/qtopengl:5
  64                 dev-qt/qtgui:5[-gles2] )
  65         pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
  66         wavpack? ( media-sound/wavpack )
  67         scrobbler? ( net-misc/curl )
  68         sndfile? ( media-libs/libsndfile )
  69         udisks? ( sys-fs/udisks:2 )"
  70 DEPEND="${RDEPEND}
  71         dev-qt/linguist-tools:5"
  72
  73 DOCS="AUTHORS ChangeLog README"
  74
  75 CMAKE_IN_SOURCE_BUILD="1"
  76
  77 REQUIRED_USE="kde? ( dbus ) "
  78
  79 src_prepare() {
  80         if has_version dev-libs/libcdio-paranoia; then
  81                 sed -i \
  82                         -e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
  83                         src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
  84         fi
  85
  86         cmake-utils_src_prepare
  87 }
  88
  89 src_configure() {
  90         mycmakeargs=(
  91                 -DUSE_alsa="$(usex alsa)"
  92                 -DUSE_aac="$(usex aac)"
  93                 -DUSE_analyzer="$(usex analyzer)"
  94                 -DUSE_bs2b="$(usex bs2b)"
  95                 -DUSE_CDA="$(usex cdda)"
  96                 -DUSE_crossfade="$(usex crossfade)"
  97                 -DUSE_cover="$(usex cover)"
  98                 -DUSE_cue="$(usex cue)"
  99                 -DUSE_curl="$(usex curl)"
 100                 -DUSE_dbus="$(usex dbus)"
 101                 -DUSE_enca="$(usex enca)"
 102                 -DUSE_ffmpeg="$(usex ffmpeg)"
 103                 -DUSE_flac="$(usex flac)"
 104                 -DUSE_GME="$(usex game)"
 105                 -DUSE_HAL=OFF
 106                 -DUSE_jack="$(usex jack)"
 107                 -DUSE_KDENOTIFY="$(usex kde)"
 108                 -DUSE_ladspa="$(usex ladspa)"
 109                 -DUSE_lyrics="$(usex lyrics)"
 110                 -DUSE_mad="$(usex mad)"
 111                 -DUSE_MIDI_WILDMIDI="$(usex midi)"
 112                 -DUSE_mplayer="$(usex mplayer)"
 113                 -DUSE_mms="$(usex mms)"
 114                 -DUSE_modplug="$(usex modplug)"
 115                 -DUSE_mpris="$(usex mpris)"
 116                 -DUSE_MPC="$(usex musepack)"
 117                 -DUSE_notifier="$(usex notifier)"
 118                 -DUSE_opus="$(usex opus)"
 119                 -DUSE_oss="$(usex oss)"
 120                 -DUSE_projectm="$(usex projectm)"
 121                 -DUSE_PULSE="$(usex pulseaudio)"
 122                 -DUSE_qsui="$(usex qsui)"
 123                 -DUSE_scrobbler="$(usex scrobbler)"
 124                 -DUSE_sndfile="$(usex sndfile)"
 125                 -DUSE_stereo="$(usex stereo)"
 126                 -DUSE_STATICON="$(usex tray)"
 127                 -DUSE_UDISKS2="$(usex udisks)"
 128                 -DUSE_SRC="$(usex libsamplerate)"
 129                 -DUSE_vorbis="$(usex vorbis)"
 130                 -DUSE_wavpack="$(usex wavpack)"
 131         )
 132
 133         cmake-utils_src_configure
 134 }