media-sound/pragha/pragha-1.3.90.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit gnome2-utils xdg-utils
   7
   8 DESCRIPTION="A lightweight music player (for Xfce)"
   9 HOMEPAGE="https://github.com/pragha-music-player/pragha"
  10 SRC_URI="https://github.com/pragha-music-player/${PN}/releases/download/V${PV}/${P}.tar.bz2"
  11
  12 LICENSE="GPL-3"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE="cdda +glyr grilo +keybinder lastfm libnotify mtp +peas +playlist rygel soup +udev"
  16
  17 COMMON_DEPEND=">=dev-db/sqlite-3.4:3=
  18         >=dev-libs/glib-2.36:=
  19         media-libs/gstreamer:1.0=
  20         media-libs/gst-plugins-base:1.0=
  21         >=media-libs/taglib-1.8:=
  22         >=x11-libs/gtk+-3.8:3=
  23         >=xfce-base/libxfce4ui-4.11:=[gtk3(+)]
  24         cdda? ( >=dev-libs/libcdio-0.90:=
  25                 >=dev-libs/libcdio-paranoia-0.90:=
  26                 >=media-libs/libcddb-1.3.0:= )
  27         glyr? ( >=media-libs/glyr-1.0.1:= )
  28         grilo? ( media-libs/grilo:0.3=[network] )
  29         keybinder? ( >=dev-libs/keybinder-0.2.0:3= )
  30         lastfm? ( >=media-libs/libclastfm-0.5:= )
  31         libnotify? ( >=x11-libs/libnotify-0.7.5:= )
  32         mtp? ( >=media-libs/libmtp-1.1.0:= )
  33         peas? ( >=dev-libs/libpeas-1.0.0:=[gtk] )
  34         playlist? ( >=dev-libs/totem-pl-parser-2.26:= )
  35         rygel? ( >=net-misc/rygel-0.26:= )
  36         soup? ( >=net-libs/libsoup-2.38:= )
  37         udev? ( virtual/libgudev:= )"
  38 RDEPEND="${COMMON_DEPEND}
  39         media-plugins/gst-plugins-meta:1.0"
  40 DEPEND="${COMMON_DEPEND}
  41         dev-util/intltool
  42         >=dev-util/xfce4-dev-tools-4.10
  43         sys-devel/gettext
  44         virtual/pkgconfig"
  45 REQUIRED_USE="glyr? ( peas )
  46         grilo? ( peas )
  47         libnotify? ( peas )
  48         mtp? ( udev )
  49         rygel? ( peas )
  50         soup? ( peas )
  51         udev? ( peas )"
  52
  53 src_configure() {
  54         local myconf=(
  55                 $(use_enable peas libpeas-1.0)
  56                 $(use_enable glyr libglyr)
  57                 $(use_enable lastfm libclastfm)
  58                 $(use_enable cdda libcdio)
  59                 $(use_enable cdda libcdio_paranoia)
  60                 $(use_enable cdda libcddb)
  61                 $(use_enable playlist totem-plparser)
  62
  63                 $(use_enable libnotify)
  64                 $(use_enable keybinder)
  65                 $(use_enable udev gudev-1.0)
  66                 $(use_enable mtp libmtp)
  67                 $(use_enable soup libsoup-2.4)
  68                 $(use_enable rygel rygel-server-2.6)
  69                 $(use_enable grilo grilo-0.3)
  70                 $(use_enable grilo grilo-net-0.3)
  71                 # avoid trying to use 0.2 & 0.3 simultaneously
  72                 # https://github.com/pragha-music-player/pragha/issues/124
  73                 --disable-grilo-0.2
  74                 --disable-grilo-net-0.2
  75         )
  76         econf "${myconf[@]}"
  77 }
  78
  79 src_install() {
  80         default
  81         find "${D}" -name '*.la' -delete || die
  82 }
  83
  84 pkg_postinst() {
  85         gnome2_icon_cache_update
  86         xdg_desktop_database_update
  87 }
  88
  89 pkg_postrm() {
  90         gnome2_icon_cache_update
  91         xdg_desktop_database_update
  92 }