media-sound/pnmixer/pnmixer-0.6_pre20111213.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit autotools eutils gnome2-utils
   8
   9 DESCRIPTION="Alsa volume mixer for the system tray"
  10 HOMEPAGE="https://github.com/nicklan/pnmixer"
  11 SRC_URI="https://dev.gentoo.org/~hasufell/distfiles/${P}.tar.xz"
  12
  13 LICENSE="GPL-3"
  14 SLOT="0"
  15 KEYWORDS="amd64 ppc x86"
  16 IUSE="debug libnotify"
  17
  18 RDEPEND="media-libs/alsa-lib
  19         x11-libs/gtk+:2
  20         x11-libs/libX11
  21         libnotify? ( x11-libs/libnotify )"
  22 DEPEND="${RDEPEND}
  23         sys-devel/gettext
  24         virtual/pkgconfig"
  25
  26 src_prepare() {
  27         epatch "${FILESDIR}"/${P}-{build,desktopfile}.patch
  28         mv configure.in configure.ac || die
  29         eautoreconf
  30 }
  31
  32 src_configure() {
  33         econf \
  34                 $(use_enable debug) \
  35                 $(use_with libnotify)
  36 }
  37
  38 src_install() {
  39         default
  40         newicon -s 128 pixmaps/${PN}-about.png ${PN}.png
  41 }
  42
  43 pkg_preinst() {
  44         gnome2_icon_savelist
  45 }
  46
  47 pkg_postinst() {
  48         gnome2_icon_cache_update
  49 }
  50
  51 pkg_postrm() {
  52         gnome2_icon_cache_update
  53 }