media-sound/pithos/pithos-1.5.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python3_{6,7,8} )
   6 inherit meson gnome2-utils virtualx python-r1
   7
   8 if [[ ${PV} =~ [9]{4,} ]]; then
   9         inherit git-r3
  10         EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
  11 else
  12         SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  13 fi
  14
  15 DESCRIPTION="Pandora.com client for the GNOME desktop"
  16 HOMEPAGE="https://pithos.github.io/"
  17
  18 LICENSE="GPL-3"
  19 SLOT="0"
  20 KEYWORDS="~amd64"
  21 IUSE="appindicator +keybinder libnotify test"
  22 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  23
  24 RDEPEND="${PYTHON_DEPS}
  25         dev-python/pygobject[${PYTHON_USEDEP}]
  26         app-crypt/libsecret[introspection]
  27         dev-libs/appstream-glib[introspection]
  28         dev-python/dbus-python[${PYTHON_USEDEP}]
  29         dev-python/pylast[${PYTHON_USEDEP}]
  30         media-libs/gstreamer:1.0[introspection]
  31         media-plugins/gst-plugins-meta:1.0[aac,http,mp3]
  32         x11-libs/gtk+:3[introspection]
  33         x11-libs/pango[introspection]
  34         x11-themes/gnome-icon-theme-symbolic
  35         appindicator? ( dev-libs/libappindicator:3[introspection] )
  36         keybinder? ( dev-libs/keybinder:3[introspection] )
  37         libnotify? ( x11-libs/libnotify[introspection] )
  38 "
  39 BDEPEND="
  40         virtual/pkgconfig
  41         test? (
  42                 ${RDEPEND}
  43                 dev-libs/glib:2
  44                 dev-util/desktop-file-utils
  45         )
  46 "
  47
  48 PATCHES=(
  49         "${FILESDIR}/pithos-1.5.0-py38.patch"
  50
  51         # comment out tests that need internet
  52         "${FILESDIR}/pithos-1.5.0-tests.patch"
  53 )
  54
  55 src_configure() {
  56         python_foreach_impl meson_src_configure
  57 }
  58
  59 src_compile() {
  60         python_foreach_impl meson_src_compile
  61 }
  62
  63 src_test() {
  64         virtx python_foreach_impl meson_src_test
  65 }
  66
  67 src_install() {
  68         python_foreach_impl meson_src_install
  69         einstalldocs
  70 }
  71
  72 pkg_postinst() {
  73         gnome2_schemas_update
  74 }
  75
  76 pkg_postrm() {
  77         gnome2_schemas_update
  78 }