media-sound/picard/picard-9999.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{5,6,7} )
   7 DISTUTILS_SINGLE_IMPL=1
   8 DISABLE_AUTOFORMATTING=true
   9 if [[ ${PV} = *9999* ]]; then
  10         EGIT_REPO_URI="https://github.com/metabrainz/picard"
  11         inherit git-r3
  12 else
  13         SRC_URI="https://musicbrainz.osuosl.org/pub/musicbrainz/${PN}/${P}.tar.gz"
  14         KEYWORDS="~amd64 ~x86"
  15 fi
  16 inherit distutils-r1 readme.gentoo-r1 xdg
  17
  18 DESCRIPTION="A cross-platform music tagger"
  19 HOMEPAGE="https://picard.musicbrainz.org"
  20
  21 LICENSE="GPL-2+"
  22 SLOT="0"
  23 IUSE="nls"
  24
  25 BDEPEND="
  26         nls? ( dev-qt/linguist-tools:5 )
  27 "
  28 RDEPEND="
  29         dev-python/PyQt5[declarative,gui,network,widgets,${PYTHON_USEDEP}]
  30         dev-qt/qtgui:5[accessibility]
  31         >=media-libs/mutagen-1.38"
  32
  33 RESTRICT="test" # doesn't work with ebuilds
  34
  35 python_compile() {
  36         local build_args=(
  37                 --disable-autoupdate
  38         )
  39         if ! use nls; then
  40                 build_args+=( --disable-locales )
  41         fi
  42         distutils-r1_python_compile ${build_args[@]}
  43 }
  44
  45 python_install() {
  46         local install_args=(
  47                 --disable-autoupdate
  48                 --skip-build
  49         )
  50         if ! use nls; then
  51                 install_args+=( --disable-locales )
  52         fi
  53         distutils-r1_python_install ${install_args[@]}
  54 }
  55
  56 python_install_all() {
  57         distutils-r1_python_install_all
  58
  59         local DOC_CONTENTS="Install optional package media-libs/chromaprint[tools] to enable
  60 calculation and lookup of AcoustID fingerprints.
  61
  62 Install optional package dev-python/python-discid to enable
  63 calculation and lookup of compact disc identifiers (disc IDs).
  64
  65 If you are upgrading Picard and it does not start, try removing
  66 Picard's settings:
  67         rm ~/.config/MusicBrainz/Picard.conf"
  68         readme.gentoo_create_doc
  69 }
  70
  71 pkg_postinst() {
  72         readme.gentoo_print_elog
  73         xdg_pkg_postinst
  74 }