media-sound/picard/picard-2.1.3-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7} )
   7 DISTUTILS_SINGLE_IMPL=1
   8 DISABLE_AUTOFORMATTING=true
   9 inherit distutils-r1 gnome2-utils readme.gentoo-r1 xdg
  10
  11 DESCRIPTION="Cross-platform music tagger"
  12 HOMEPAGE="https://picard.musicbrainz.org"
  13 SRC_URI="https://musicbrainz.osuosl.org/pub/musicbrainz/${PN}/${P}.tar.gz"
  14
  15 LICENSE="GPL-2+"
  16 SLOT="0"
  17 KEYWORDS="amd64 x86"
  18 IUSE="nls"
  19
  20 RDEPEND="
  21         $(python_gen_cond_dep '
  22                 dev-python/PyQt5[declarative,gui,network,widgets,${PYTHON_MULTI_USEDEP}]
  23         ')
  24         dev-qt/qtgui:5
  25         >=media-libs/mutagen-1.38"
  26 DEPEND="
  27         nls? ( dev-qt/linguist-tools:5 )
  28 "
  29
  30 RESTRICT="test" # doesn't work with ebuilds
  31
  32 S="${WORKDIR}/${PN}-release-${PV}"
  33
  34 python_compile() {
  35         local build_args=(
  36                 --disable-autoupdate
  37         )
  38         if ! use nls; then
  39                 build_args+=( --disable-locales )
  40         fi
  41         distutils-r1_python_compile ${build_args[@]}
  42 }
  43
  44 python_install() {
  45         local install_args=(
  46                 --disable-autoupdate
  47                 --skip-build
  48         )
  49         if ! use nls; then
  50                 install_args+=( --disable-locales )
  51         fi
  52         distutils-r1_python_install ${install_args[@]}
  53 }
  54
  55 python_install_all() {
  56         distutils-r1_python_install_all
  57
  58         local DOC_CONTENTS="Install optional package media-libs/chromaprint[tools] to enable
  59 calculation and lookup of AcoustID fingerprints.
  60
  61 Install optional package dev-python/python-discid to enable
  62 calculation and lookup of compact disc identifiers (disc IDs).
  63
  64 If you are upgrading Picard and it does not start, try removing
  65 Picard's settings:
  66         rm ~/.config/MusicBrainz/Picard.conf"
  67         readme.gentoo_create_doc
  68 }
  69
  70 pkg_postinst() {
  71         readme.gentoo_print_elog
  72         xdg_pkg_postinst
  73 }