media-sound/pianobar/pianobar-9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit toolchain-funcs flag-o-matic
   7
   8 if [[ ${PV} == 9999 ]]; then
   9         inherit git-r3
  10         EGIT_REPO_URI="https://github.com/PromyLOPh/pianobar.git"
  11 else
  12         SRC_URI="https://6xq.net/${PN}/${P}.tar.bz2"
  13         KEYWORDS="~amd64 ~x86"
  14 fi
  15
  16 DESCRIPTION="A console-based replacement for Pandora's flash player"
  17 HOMEPAGE="https://6xq.net/pianobar/"
  18
  19 LICENSE="MIT"
  20 SLOT="0"
  21 IUSE=""
  22
  23 BDEPEND="virtual/pkgconfig"
  24 RDEPEND="
  25         dev-libs/json-c:=
  26         dev-libs/libgcrypt:0=
  27         media-libs/libao
  28         >=media-video/ffmpeg-3.3:0=
  29         net-misc/curl
  30 "
  31 DEPEND="${RDEPEND}"
  32
  33 src_compile() {
  34         append-cflags -std=c99
  35         tc-export AR CC
  36         emake V=1 DYNLINK=1
  37 }
  38
  39 src_install() {
  40         emake DESTDIR="${D}" PREFIX=/usr LIBDIR=/usr/$(get_libdir) DYNLINK=1 install
  41         dodoc ChangeLog README.md
  42
  43         rm "${D}"/usr/lib*/*.a || die
  44
  45         docinto contrib
  46         dodoc -r contrib/{config-example,*.sh,eventcmd-examples}
  47         docompress -x /usr/share/doc/${PF}/contrib
  48 }