media-sound/patchage/patchage-0.5.0-r2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python2_7 )
   6 PYTHON_REQ_USE='threads(+)'
   7
   8 inherit flag-o-matic gnome2-utils waf-utils python-any-r1
   9
  10 DESCRIPTION="Modular patch bay for audio and MIDI systems"
  11 HOMEPAGE="http://drobilla.net/software/patchage"
  12 SRC_URI="http://download.drobilla.net/${P}.tar.bz2"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17 IUSE="alsa debug lash"
  18
  19 RDEPEND=">=media-libs/raul-0.7.0
  20         >=x11-libs/flowcanvas-0.7.1
  21         >=dev-cpp/gtkmm-2.11.12:2.4
  22         >=dev-cpp/glibmm-2.14:2
  23         >=dev-cpp/libglademm-2.6.0:2.4
  24         dev-cpp/libgnomecanvasmm:2.6
  25         virtual/jack
  26         alsa? ( media-libs/alsa-lib )
  27         lash? ( dev-libs/dbus-glib )"
  28 DEPEND="${RDEPEND}
  29         ${PYTHON_DEPS}
  30         dev-libs/boost
  31         virtual/pkgconfig"
  32
  33 DOCS=( AUTHORS README ChangeLog )
  34
  35 PATCHES=(
  36         "${FILESDIR}"/${P}-desktop.patch
  37 )
  38
  39 src_configure() {
  40         append-cxxflags -std=c++11
  41         waf-utils_src_configure \
  42                 $(use debug && echo "--debug") \
  43                 $(use alsa || echo "--no-alsa") \
  44                 $(use lash || echo "--no-lash")
  45 }
  46
  47 pkg_postinst() {
  48         gnome2_icon_cache_update
  49 }
  50
  51 pkg_postrm() {
  52         gnome2_icon_cache_update
  53 }