media-sound/opus-tools/opus-tools-0.1.10.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6 inherit autotools
   7
   8 DESCRIPTION="Royalty-free, highly versatile audio codec"
   9 HOMEPAGE="http://opus-codec.org/"
  10
  11 if [[ ${PV} == *9999 ]] ; then
  12         inherit git-2
  13         EGIT_REPO_URI="git://git.opus-codec.org/${PN}.git"
  14 elif [[ ${PV%_p*} != ${PV} ]] ; then # Gentoo snapshot
  15         SRC_URI="https://dev.gentoo.org/~lu_zero/${PN}/${P}.tar.xz"
  16 else # Official release
  17         SRC_URI="http://downloads.xiph.org/releases/opus/${P}.tar.gz"
  18 fi
  19
  20 LICENSE="BSD-2"
  21 SLOT="0"
  22 KEYWORDS="~amd64 ~ppc64 ~x86"
  23 IUSE="flac"
  24
  25 RDEPEND=">=media-libs/libogg-1.3.0
  26          >=media-libs/opus-1.0.3
  27          flac? ( >=media-libs/flac-1.1.3 )"
  28 DEPEND="virtual/pkgconfig
  29         ${RDEPEND}"
  30
  31 src_prepare() {
  32         default
  33         [[ ${PV} == *9999 ]] && eautoreconf
  34 }
  35
  36 src_configure() {
  37         econf $(use_with flac)
  38 }
  39
  40 src_install() {
  41         default
  42         find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
  43 }