media-sound/ncmpcpp/ncmpcpp-0.8.2-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="featureful ncurses based MPD client inspired by ncmpc"
   7 HOMEPAGE="https://rybczak.net/ncmpcpp/"
   8 SRC_URI="https://rybczak.net/ncmpcpp/stable/${P}.tar.bz2"
   9
  10 LICENSE="GPL-2"
  11 SLOT="0"
  12 KEYWORDS="amd64 ~arm ~ppc ~ppc64 ~sparc x86"
  13 IUSE="clock outputs taglib visualizer"
  14
  15 RDEPEND="
  16         !dev-libs/boost:0/1.57.0
  17         >=media-libs/libmpdclient-2.1
  18         dev-libs/boost:=[icu,nls,threads]
  19         dev-libs/icu:=
  20         net-misc/curl
  21         sys-libs/ncurses:=[unicode]
  22         sys-libs/readline:*
  23         taglib? ( media-libs/taglib )
  24         visualizer? ( sci-libs/fftw:3.0= )
  25 "
  26 DEPEND="${RDEPEND}"
  27 BDEPEND="virtual/pkgconfig"
  28
  29 # https://github.com/ncmpcpp/ncmpcpp/pull/385
  30 PATCHES=( "${FILESDIR}/${P}-gcc10.patch" )
  31
  32 src_prepare() {
  33         default
  34
  35         sed -i -e '/^docdir/d' {,doc/}Makefile{.am,.in} || die
  36         sed -i -e 's|COPYING||g' Makefile{.am,.in} || die
  37 }
  38
  39 src_configure() {
  40         econf \
  41                 $(use_enable clock) \
  42                 $(use_enable outputs) \
  43                 $(use_enable visualizer) \
  44                 $(use_with taglib) \
  45                 $(use_with visualizer fftw)
  46 }
  47
  48 src_install() {
  49         default
  50
  51         dodoc doc/{bindings,config}
  52 }
  53
  54 pkg_postinst() {
  55         echo
  56         elog "Example configuration files have been installed at"
  57         elog "${EROOT}/usr/share/doc/${PF}"
  58         elog "${P} uses ~/.ncmpcpp/config and ~/.ncmpcpp/bindings"
  59         elog "as user configuration files."
  60         echo
  61         if use visualizer; then
  62         elog "If you want to use the visualizer, you need mpd with fifo enabled."
  63         echo
  64         fi
  65 }