media-sound/ncmpc/ncmpc-0.34.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit meson
   7
   8 DESCRIPTION="Ncurses client for the Music Player Daemon (MPD)"
   9 HOMEPAGE="https://www.musicpd.org/clients/ncmpc/ https://github.com/MusicPlayerDaemon/ncmpc"
  10 SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
  11
  12 LICENSE="GPL-2+"
  13 SLOT="0"
  14 KEYWORDS="amd64 ppc ppc64 ~sparc x86"
  15 IUSE="async-connect chat-screen doc +help-screen key-screen +library-screen lirc lyrics-screen +mouse nls outputs-screen pcre search-screen +song-screen"
  16
  17 BDEPEND="
  18         virtual/pkgconfig
  19         doc? ( dev-python/sphinx )
  20 "
  21 RDEPEND="
  22         >=media-libs/libmpdclient-2.9
  23         sys-libs/ncurses:0=[unicode]
  24         lirc? ( app-misc/lirc )
  25         pcre? ( dev-libs/libpcre )
  26 "
  27 DEPEND="${RDEPEND}
  28         >=dev-libs/boost-1.62
  29 "
  30
  31 src_prepare() {
  32         default
  33
  34         # use correct docdir and don't install license file
  35         sed -e "/^docdir =/s/meson.project_name()/'${PF}'/" \
  36                 -e "s/'COPYING', //" \
  37                 -i meson.build || die
  38
  39         # use correct (html) docdir
  40         sed -e "/install_dir:.*doc/s/meson.project_name()/'${PF}'/" \
  41                 -i doc/meson.build || die
  42 }
  43
  44 src_configure() {
  45         local emesonargs=(
  46                 -Dcurses=ncursesw
  47                 -Dcolors=true
  48                 -Dmini=false
  49                 -Dlyrics_plugin_dir="${EPREFIX}/usr/$(get_libdir)/ncmpc/lyrics"
  50                 -Dasync_connect=$(usex async-connect true false)
  51                 -Dchat_screen=$(usex chat-screen true false)
  52                 -Ddocumentation=$(usex doc enabled disabled)
  53                 -Dhelp_screen=$(usex help-screen true false)
  54                 -Dkey_screen=$(usex key-screen true false)
  55                 -Dlibrary_screen=$(usex library-screen true false)
  56                 -Dlirc=$(usex lirc enabled disabled)
  57                 -Dlocale=$(usex nls enabled disabled)
  58                 -Dlyrics_screen=$(usex lyrics-screen true false)
  59                 -Dmouse=$(usex mouse enabled disabled)
  60                 -Dmultibyte=$(usex nls true false)
  61                 -Dnls=$(usex nls enabled disabled)
  62                 -Doutputs_screen=$(usex outputs-screen true false)
  63                 -Dregex=$(usex pcre enabled disabled)
  64                 -Dsearch_screen=$(usex search-screen true false)
  65                 -Dsong_screen=$(usex song-screen true false)
  66         )
  67
  68         meson_src_configure
  69 }