media-sound/mpd/mpd-0.21.16-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic linux-info meson systemd xdg-utils
   7
   8 DESCRIPTION="The Music Player Daemon (mpd)"
   9 HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/MPD"
  10 SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="alpha amd64 ~arm ~hppa ~ppc ~ppc64 ~sh x86 ~x64-macos"
  15 IUSE="adplug +alsa ao audiofile bzip2 cdio chromaprint +cue +curl +dbus debug
  16         +eventfd expat faad +ffmpeg +fifo flac fluidsynth gme +icu +id3tag +inotify
  17         +ipv6 jack lame libav libmpdclient libsamplerate libsoxr +mad mikmod mms
  18         modplug mpg123 musepack +network nfs openal opus oss pipe pulseaudio qobuz
  19         recorder samba selinux sid signalfd sndfile soundcloud sqlite systemd
  20         test tidal twolame udisks unicode vorbis wavpack webdav wildmidi upnp
  21         zeroconf zip zlib"
  22
  23 OUTPUT_PLUGINS="alsa ao fifo jack network openal oss pipe pulseaudio recorder"
  24 DECODER_PLUGINS="adplug audiofile faad ffmpeg flac fluidsynth mad mikmod
  25         modplug mpg123 musepack flac sid vorbis wavpack wildmidi"
  26 ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
  27
  28 REQUIRED_USE="
  29         || ( ${OUTPUT_PLUGINS} )
  30         || ( ${DECODER_PLUGINS} )
  31         network? ( || ( ${ENCODER_PLUGINS} ) )
  32         recorder? ( || ( ${ENCODER_PLUGINS} ) )
  33         upnp? ( expat )
  34         webdav? ( curl expat )
  35         "
  36
  37 RESTRICT="!test? ( test )"
  38
  39 RDEPEND="
  40         acct-user/mpd
  41         adplug? ( media-libs/adplug:= )
  42         alsa? (
  43                 media-libs/alsa-lib
  44                 media-sound/alsa-utils
  45         )
  46
  47         ao? ( media-libs/libao[alsa?,pulseaudio?] )
  48         audiofile? ( media-libs/audiofile:= )
  49
  50         cdio? (
  51                 dev-libs/libcdio:=
  52                 dev-libs/libcdio-paranoia
  53         )
  54
  55         chromaprint? ( media-libs/chromaprint )
  56         curl? ( net-misc/curl )
  57         dbus? ( sys-apps/dbus )
  58         expat? ( dev-libs/expat )
  59         faad? ( media-libs/faad2 )
  60
  61         ffmpeg? (
  62                 libav? ( media-video/libav:0= )
  63                 !libav? ( media-video/ffmpeg:0= )
  64         )
  65
  66         flac? ( media-libs/flac )
  67         fluidsynth? ( media-sound/fluidsynth )
  68         gme? ( >=media-libs/game-music-emu-0.6.0_pre20120802 )
  69         icu? (  dev-libs/icu:= )
  70         id3tag? ( media-libs/libid3tag )
  71         jack? ( virtual/jack )
  72         lame? ( network? ( media-sound/lame ) )
  73         libmpdclient? ( media-libs/libmpdclient )
  74         libsamplerate? ( media-libs/libsamplerate )
  75         libsoxr? ( media-libs/soxr )
  76         mad? ( media-libs/libmad )
  77         mikmod? ( media-libs/libmikmod )
  78         mms? ( media-libs/libmms )
  79         modplug? ( media-libs/libmodplug )
  80         mpg123? ( media-sound/mpg123 )
  81         musepack? ( media-sound/musepack-tools )
  82         network? ( media-libs/libshout )
  83         nfs? ( net-fs/libnfs )
  84         openal? ( media-libs/openal )
  85         opus? ( media-libs/opus )
  86         pulseaudio? ( media-sound/pulseaudio )
  87         qobuz? ( dev-libs/libgcrypt:0 )
  88         samba? ( net-fs/samba )
  89         selinux? ( sec-policy/selinux-mpd )
  90         sid? ( || (
  91                 media-libs/libsidplay:2
  92                 media-libs/libsidplayfp
  93         ) )
  94         sndfile? ( media-libs/libsndfile )
  95         soundcloud? ( >=dev-libs/yajl-2:= )
  96         sqlite? ( dev-db/sqlite:3 )
  97         systemd? ( sys-apps/systemd )
  98         tidal? ( dev-libs/yajl
  99                 net-misc/curl )
 100         twolame? ( media-sound/twolame )
 101         udisks? ( sys-fs/udisks:2 )
 102         upnp? ( net-libs/libupnp:0 )
 103         vorbis? ( media-libs/libvorbis )
 104         wavpack? ( media-sound/wavpack )
 105         wildmidi? ( media-sound/wildmidi )
 106         zeroconf? ( net-dns/avahi[dbus] )
 107         zip? ( dev-libs/zziplib )
 108         zlib? ( sys-libs/zlib:= )"
 109
 110 DEPEND="${RDEPEND}
 111         >=dev-libs/boost-1.58:=
 112         test? ( dev-cpp/gtest )"
 113
 114 BDEPEND=">=dev-util/meson-0.49.2
 115         virtual/pkgconfig"
 116
 117 PATCHES=(
 118         "${FILESDIR}"/${PN}-0.18.conf.patch
 119 )
 120
 121 pkg_setup() {
 122         if use eventfd; then
 123                 CONFIG_CHECK+=" ~EVENTFD"
 124                 ERROR_EVENTFD="${P} requires eventfd in-kernel support."
 125         fi
 126
 127         if use signalfd; then
 128                 CONFIG_CHECK+=" ~SIGNALFD"
 129                 ERROR_SIGNALFD="${P} requires signalfd in-kernel support."
 130         fi
 131
 132         if use inotify; then
 133                 CONFIG_CHECK+=" ~INOTIFY_USER"
 134                 ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
 135         fi
 136
 137         if use eventfd || use signalfd || use inotify; then
 138                 linux-info_pkg_setup
 139         fi
 140
 141         elog "If you will be starting mpd via /etc/init.d/mpd, please make
 142         sure that MPD's pid_file is _set_."
 143 }
 144
 145 src_prepare() {
 146         cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
 147         default
 148 }
 149
 150 src_configure() {
 151         local emesonargs=(
 152                 -Dbzip2=$(usex bzip2 enabled disabled)
 153                 -Dcdio_paranoia=$(usex cdio enabled disabled)
 154                 -Dchromaprint=$(usex chromaprint enabled disabled)
 155                 -Dcue=$(usex cue true false)
 156                 -Dcurl=$(usex curl enabled disabled)
 157                 -Ddbus=$(usex dbus enabled disabled)
 158                 -Ddebug=$(usex debug true false)
 159                 -Deventfd=$(usex eventfd true false)
 160                 -Dexpat=$(usex expat enabled disabled)
 161                 -Dicu=$(usex icu enabled disabled)
 162                 -Did3tag=$(usex id3tag enabled disabled)
 163                 -Dinotify=$(usex inotify true false)
 164                 -Dipv6=$(usex ipv6 enabled disabled)
 165                 -Diso9660=$(usex cdio enabled disabled)
 166                 -Dlibmpdclient=$(usex libmpdclient enabled disabled)
 167                 -Dlibsamplerate=$(usex libsamplerate enabled disabled)
 168                 -Dmms=$(usex mms enabled disabled)
 169                 -Dnfs=$(usex nfs enabled disabled)
 170                 -Dsignalfd=$(usex signalfd true false)
 171                 -Dsmbclient=$(usex samba enabled disabled)
 172                 -Dsoxr=$(usex libsoxr enabled disabled)
 173                 -Dsqlite=$(usex sqlite enabled disabled)
 174                 -Dsystemd=$(usex systemd enabled disabled)
 175                 -Dtest=$(usex test true false)
 176                 -Dudisks=$(usex udisks enabled disabled)
 177                 -Dupnp=$(usex upnp enabled disabled)
 178                 -Dwebdav=$(usex webdav enabled disabled)
 179                 -Dzeroconf=$(usex zeroconf avahi disabled)
 180                 -Dzlib=$(usex zlib enabled disabled)
 181                 -Dzzip=$(usex zip enabled disabled)
 182                 )
 183
 184         emesonargs+=(
 185                 -Dalsa=$(usex alsa enabled disabled)
 186                 -Dao=$(usex ao enabled disabled)
 187                 -Dfifo=$(usex fifo true false)
 188                 -Djack=$(usex jack enabled disabled)
 189                 -Dopenal=$(usex openal enabled disabled)
 190                 -Doss=$(usex oss enabled disabled)
 191                 -Dpipe=$(usex pipe true false)
 192                 -Dpulse=$(usex pulseaudio enabled disabled)
 193                 -Drecorder=$(usex recorder true false)
 194         )
 195
 196         if use samba || use upnp; then
 197                 emesonargs+=( -Dneighbor=true )
 198         fi
 199
 200         append-lfs-flags
 201         append-ldflags "-L/usr/$(get_libdir)/sidplay/builders"
 202
 203         if use network; then
 204
 205         emesonargs+=(
 206                 -Dshine=disabled
 207                 -Dshout=enabled
 208                 -Dvorbisenc=$(usex vorbis enabled disabled)
 209                 -Dhttpd=true
 210                 -Dlame=$(usex lame enabled disabled)
 211                 -Dtwolame=$(usex twolame enabled disabled)
 212                 -Dwave_encoder=$(usex audiofile true false)
 213         )
 214         fi
 215
 216         emesonargs+=(
 217                 -Dadplug=$(usex adplug enabled disabled)
 218                 -Daudiofile=$(usex audiofile enabled disabled)
 219                 -Dfaad=$(usex faad enabled disabled)
 220                 -Dffmpeg=$(usex ffmpeg enabled disabled)
 221                 -Dflac=$(usex flac enabled disabled)
 222                 -Dfluidsynth=$(usex fluidsynth enabled disabled)
 223                 -Dgme=$(usex gme enabled disabled)
 224                 -Dmad=$(usex mad enabled disabled)
 225                 -Dmikmod=$(usex mikmod enabled disabled)
 226                 -Dmodplug=$(usex modplug enabled disabled)
 227                 -Dmpcdec=$(usex musepack enabled disabled)
 228                 -Dmpg123=$(usex mpg123 enabled disabled)
 229                 -Dopus=$(usex opus enabled disabled)
 230                 -Dsidplay=$(usex sid enabled disabled)
 231                 -Dsndfile=$(usex sndfile enabled disabled)
 232                 -Dvorbis=$(usex vorbis enabled disabled)
 233                 -Dwavpack=$(usex wavpack enabled disabled)
 234                 -Dwildmidi=$(usex wildmidi enabled disabled)
 235
 236         )
 237
 238         emesonargs+=(
 239                 -Dqobuz=$(usex qobuz enabled disabled)
 240                 -Dsoundcloud=$(usex soundcloud enabled disabled)
 241                 -Dtidal=$(usex tidal enabled disabled)
 242         )
 243
 244         emesonargs+=(
 245                 --libdir="/usr/$(get_libdir)"
 246                 -Ddocumentation=false
 247                 -Dsndio=disabled #not yet in the tree
 248                 -Dsolaris_output=disabled
 249
 250                 -Ddatabase=true
 251                 -Ddsd=true
 252                 -Dtcp=true
 253
 254                 -Dsystemd_system_unit_dir="$(systemd_get_systemunitdir)"
 255                 -Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
 256                 )
 257
 258         if use icu; then
 259                 emesonargs+=( -Diconv=enabled )
 260         else
 261                 emesonargs+=( -Diconv=disabled )
 262         fi
 263
 264         meson_src_configure
 265 }
 266
 267 src_install() {
 268         meson_src_install
 269
 270         insinto /etc
 271         newins doc/mpdconf.dist mpd.conf
 272
 273         insinto /etc/logrotate.d
 274         newins "${FILESDIR}"/${PN}-0.21.1.logrotate ${PN}
 275
 276         newinitd "${FILESDIR}"/${PN}-0.21.4.init ${PN}
 277
 278         if use unicode; then
 279                 sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
 280                         "${ED}"/etc/mpd.conf || die "sed failed"
 281         fi
 282
 283         doman doc/mpd.1
 284         doman doc/mpd.conf.5
 285
 286         keepdir /var/lib/mpd
 287         keepdir /var/lib/mpd/music
 288         keepdir /var/lib/mpd/playlists
 289
 290 }
 291
 292 pkg_postinst() {
 293         xdg_icon_cache_update
 294 }
 295
 296 pkg_postrm() {
 297         xdg_icon_cache_update
 298 }