media-sound/mpc/mpc-0.30.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit bash-completion-r1 meson
   7
   8 DESCRIPTION="A commandline client for Music Player Daemon (media-sound/mpd)"
   9 HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/mpc"
  10 SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 arm ppc ppc64 ~sparc x86"
  15 IUSE="iconv test"
  16 RESTRICT="!test? ( test )"
  17
  18 RDEPEND="media-libs/libmpdclient
  19         iconv? ( virtual/libiconv )"
  20
  21 DEPEND="${RDEPEND}
  22         dev-python/sphinx
  23         virtual/pkgconfig
  24         test? ( dev-libs/check )"
  25
  26 src_configure() {
  27         local emesonargs=(
  28                 -Dtest=$(usex test true false)
  29                 -Diconv=$(usex iconv true false)
  30         )
  31         meson_src_configure
  32 }
  33
  34 src_install() {
  35         meson_src_install
  36         newbashcomp contrib/mpc-completion.bash mpc
  37 }