media-sound/mp3c/mp3c-0.31-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic toolchain-funcs
   7
   8 DESCRIPTION="console based mp3 ripper, with cddb support"
   9 HOMEPAGE="http://wspse.de/WSPse/Linux-MP3c.php3"
  10 SRC_URI="ftp://ftp.wspse.de/pub/linux/wspse/${P}.tar.bz2"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 ppc sparc x86"
  15 IUSE="mp3 vorbis"
  16
  17 DEPEND="sys-libs/ncurses:0="
  18 RDEPEND="
  19         ${DEPEND}
  20         virtual/cdrtools
  21         mp3? (
  22                 media-sound/lame
  23                 media-sound/mp3info
  24         )
  25         vorbis? ( media-sound/vorbis-tools )"
  26 BDEPEND="virtual/pkgconfig"
  27
  28 PATCHES=( "${FILESDIR}"/${PN}-buffer.patch )
  29
  30 src_configure() {
  31         append-libs $($(tc-getPKG_CONFIG) --libs ncurses)
  32         econf $(use_enable vorbis oggdefaults)
  33 }
  34
  35 src_install() {
  36         default
  37         dodoc BATCH.README CDDB_HOWTO OTHERS
  38 }