media-sound/moc/moc-2.5.2-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 MY_P=${P/_/-}
   7 DESCRIPTION="Music On Console - ncurses interface for playing audio files"
   8 HOMEPAGE="https://moc.daper.net"
   9 SRC_URI="http://ftp.daper.net/pub/soft/moc/stable/${MY_P}.tar.bz2"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~alpha amd64 ppc ppc64 sparc x86"
  14 IUSE="aac alsa +cache curl debug ffmpeg flac jack libsamplerate mad +magic modplug musepack
  15         oss sid sndfile speex timidity tremor +unicode vorbis wavpack"
  16
  17 RDEPEND=">=dev-libs/libltdl-2:0
  18         sys-libs/ncurses:0=[unicode?]
  19         aac? ( media-libs/faad2 )
  20         alsa? ( media-libs/alsa-lib )
  21         cache? ( >=sys-libs/db-4:= )
  22         curl? ( net-misc/curl )
  23         ffmpeg? ( media-video/ffmpeg )
  24         flac? ( media-libs/flac )
  25         jack? ( media-sound/jack-audio-connection-kit )
  26         libsamplerate? ( media-libs/libsamplerate )
  27         mad? ( media-libs/libmad sys-libs/zlib media-libs/libid3tag )
  28         magic? ( sys-apps/file )
  29         modplug? ( media-libs/libmodplug )
  30         musepack? ( media-sound/musepack-tools media-libs/taglib )
  31         sid? ( >=media-libs/libsidplay-2 )
  32         sndfile? ( media-libs/libsndfile )
  33         speex? ( media-libs/speex )
  34         timidity? ( media-libs/libtimidity media-sound/timidity++ )
  35         vorbis? (
  36                 media-libs/libogg
  37                 tremor? ( media-libs/tremor )
  38                 !tremor? ( media-libs/libvorbis )
  39         )
  40         wavpack? ( media-sound/wavpack )"
  41 DEPEND="${RDEPEND}
  42         app-arch/xz-utils
  43         virtual/pkgconfig"
  44
  45 S=${WORKDIR}/${MY_P}
  46
  47 src_configure() {
  48         local myconf=(
  49                 $(use_enable debug)
  50                 $(use_enable cache)
  51                 $(use_with oss)
  52                 $(use_with alsa)
  53                 $(use_with jack)
  54                 $(use_with magic)
  55                 $(use_with unicode ncursesw)
  56                 $(use_with libsamplerate samplerate)
  57                 $(use_with aac)
  58                 $(use_with ffmpeg)
  59                 $(use_with flac)
  60                 $(use_with modplug)
  61                 $(use_with mad mp3)
  62                 --without-rcc
  63                 $(use_with musepack)
  64                 $(use_with sid sidplay2)
  65                 $(use_with sndfile)
  66                 $(use_with speex)
  67                 $(use_with timidity)
  68                 $(use_with vorbis vorbis $(usex tremor tremor ""))
  69                 $(use_with wavpack)
  70                 $(use_with curl)
  71         )
  72
  73         econf "${myconf[@]}"
  74 }
  75
  76 src_install() {
  77         default
  78         find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
  79 }