media-sound/moc/moc-2.5.0.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 MY_P=${P/_/-}
   8 DESCRIPTION="Music On Console - ncurses interface for playing audio files"
   9 HOMEPAGE="http://moc.daper.net"
  10 SRC_URI="http://ftp.daper.net/pub/soft/moc/stable/${MY_P}.tar.bz2"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="alpha amd64 ppc ppc64 sparc x86"
  15 IUSE="aac alsa +cache curl debug ffmpeg flac jack libsamplerate mad +magic modplug musepack
  16         oss sid sndfile speex timidity tremor +unicode vorbis wavpack"
  17
  18 RDEPEND=">=dev-libs/libltdl-2:0
  19         sys-libs/ncurses[unicode?]
  20         aac? ( media-libs/faad2 )
  21         alsa? ( media-libs/alsa-lib )
  22         cache? ( >=sys-libs/db-4 )
  23         curl? ( net-misc/curl )
  24         ffmpeg? ( virtual/ffmpeg )
  25         flac? ( media-libs/flac )
  26         jack? ( media-sound/jack-audio-connection-kit )
  27         libsamplerate? ( media-libs/libsamplerate )
  28         mad? ( media-libs/libmad sys-libs/zlib media-libs/libid3tag )
  29         magic? ( sys-apps/file )
  30         modplug? ( media-libs/libmodplug )
  31         musepack? ( media-sound/musepack-tools media-libs/taglib )
  32         sid? ( >=media-libs/libsidplay-2 )
  33         sndfile? ( media-libs/libsndfile )
  34         speex? ( media-libs/speex )
  35         timidity? ( media-libs/libtimidity media-sound/timidity++ )
  36         vorbis? (
  37                 media-libs/libogg
  38                 tremor? ( media-libs/tremor )
  39                 !tremor? ( media-libs/libvorbis )
  40         )
  41         wavpack? ( media-sound/wavpack )"
  42 DEPEND="${RDEPEND}
  43         app-arch/xz-utils
  44         virtual/pkgconfig"
  45
  46 S=${WORKDIR}/${MY_P}
  47
  48 src_configure() {
  49         local myconf=(
  50                 --docdir="${EPREFIX}"/usr/share/doc/${PF}
  51                 $(use_enable debug)
  52                 $(use_enable cache)
  53                 $(use_with oss)
  54                 $(use_with alsa)
  55                 $(use_with jack)
  56                 $(use_with magic)
  57                 $(use_with unicode ncursesw)
  58                 $(use_with libsamplerate samplerate)
  59                 $(use_with aac)
  60                 $(use_with ffmpeg)
  61                 $(use_with flac)
  62                 $(use_with modplug)
  63                 $(use_with mad mp3)
  64                 --without-rcc
  65                 $(use_with musepack)
  66                 $(use_with sid sidplay2)
  67                 $(use_with sndfile)
  68                 $(use_with speex)
  69                 $(use_with timidity)
  70                 $(use_with vorbis vorbis $(usex tremor tremor ""))
  71                 $(use_with wavpack)
  72                 $(use_with curl)
  73         )
  74
  75         econf "${myconf[@]}"
  76 }
  77
  78 src_install() {
  79         default
  80         find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
  81 }