media-sound/loudness-scanner/loudness-scanner-9999.ebuild

   1 # Copyright 2019-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cmake git-r3
   7
   8 DESCRIPTION="Scans your music files and tags them with loudness information"
   9 HOMEPAGE="https://github.com/jiixyj/loudness-scanner/"
  10 EGIT_REPO_URI="https://github.com/jiixyj/loudness-scanner.git"
  11
  12 LICENSE="MIT"
  13 SLOT="0"
  14 KEYWORDS=""
  15 IUSE="+ffmpeg gtk mpg123 musepack qt5 sndfile"
  16 REQUIRED_USE="|| ( sndfile ffmpeg mpg123 musepack )"
  17
  18 DEPEND="
  19         dev-libs/glib
  20         media-libs/libebur128
  21         media-libs/taglib
  22         ffmpeg? ( media-video/ffmpeg )
  23         mpg123? ( media-sound/mpg123 )
  24         musepack? ( media-sound/musepack-tools )
  25         sndfile? ( media-libs/libsndfile )
  26         gtk? (
  27                 gnome-base/librsvg:2
  28                 x11-libs/cairo
  29                 x11-libs/gtk+:2
  30         )
  31         qt5? (
  32                 dev-qt/qtcore:5
  33                 dev-qt/qtgui:5
  34                 dev-qt/qtsvg:5
  35                 dev-qt/qtwidgets:5
  36         )
  37 "
  38 RDEPEND="${DEPEND}"
  39
  40 src_prepare() {
  41         cmake_src_prepare
  42         sed -i -e 's|".",|"'${EROOT}'/usr/'$(get_libdir)'/loudness-scanner",|g' \
  43                 "${S}"/scanner/inputaudio/input.c
  44 }
  45
  46 src_configure() {
  47         local -a mycmakeargs=(
  48                 -DCMAKE_SKIP_RPATH=ON
  49                 -DBUILD_SHARED_LIBS:BOOL=OFF # use static internal libraries
  50                 -DDISABLE_FFMPEG:BOOL=$(usex ffmpeg no yes)
  51                 -DDISABLE_GSTREAMER:BOOL=ON # depends on obsolete gstreamer-0.10
  52                 -DDISABLE_GTK2:BOOL=$(usex gtk no yes)
  53                 -DDISABLE_MPCDEC:BOOL=$(usex musepack no yes)
  54                 -DDISABLE_MPG123:BOOL=$(usex mpg123 no yes)
  55                 -DDISABLE_QT4:BOOL=ON
  56                 -DDISABLE_QT5:BOOL=$(usex qt5 no yes)
  57                 -DDISABLE_RSVG2:BOOL=$(usex gtk no yes)
  58                 -DDISABLE_SNDFILE:BOOL=$(usex sndfile no yes)
  59         )
  60         cmake_src_configure
  61 }
  62
  63 src_install() {
  64         dobin "${BUILD_DIR}"/loudness
  65         use gtk && dobin "${BUILD_DIR}"/loudness-drop-gtk
  66         use qt5 && dobin "${BUILD_DIR}"/loudness-drop-qt5
  67
  68         insinto /usr/$(get_libdir)/loudness-scanner
  69         doins "${BUILD_DIR}"/libinput_*.so
  70
  71         einstalldocs
  72 }