media-sound/klick/klick-0.12.2-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7
   8 inherit python-any-r1 scons-utils toolchain-funcs
   9
  10 DESCRIPTION="An advanced command-line based metronome for JACK"
  11 HOMEPAGE="http://das.nasophon.de/klick"
  12 SRC_URI="http://das.nasophon.de/download/${P}.tar.gz"
  13
  14 LICENSE="GPL-2+"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~ppc ~x86"
  17 IUSE="debug osc rubberband"
  18
  19 RDEPEND="media-libs/libsamplerate
  20         media-libs/libsndfile
  21         virtual/jack
  22         osc? ( media-libs/liblo )
  23         rubberband? ( media-libs/rubberband )"
  24 DEPEND="${RDEPEND}
  25         dev-libs/boost"
  26 BDEPEND="virtual/pkgconfig"
  27
  28 PATCHES=(
  29         "${FILESDIR}"/${P}-sconstruct.patch
  30         "${FILESDIR}"/${P}-gcc6.patch
  31 )
  32
  33 HTML_DOCS=( doc/manual.html )
  34
  35 src_configure() {
  36         MYSCONS=(
  37                 CXX="$(tc-getCXX)"
  38                 CXXFLAGS="${CXXFLAGS}"
  39                 LINKFLAGS="${LDFLAGS}"
  40                 PREFIX="${EPREFIX}/usr"
  41                 DESTDIR="${D}"
  42                 DEBUG=$(usex debug)
  43                 OSC=$(usex osc)
  44                 RUBBERBAND=$(usex rubberband)
  45         )
  46 }
  47
  48 src_compile() {
  49         escons "${MYSCONS[@]}"
  50 }
  51
  52 src_install() {
  53         escons "${MYSCONS[@]}" install
  54         einstalldocs
  55 }