media-sound/jack-rack/jack-rack-1.4.7-r1.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=4
   6 inherit autotools eutils flag-o-matic toolchain-funcs
   7
   8 DESCRIPTION="JACK Rack is an effects rack for the JACK low latency audio API"
   9 HOMEPAGE="http://jack-rack.sourceforge.net/"
  10 SRC_URI="mirror://sourceforge/jack-rack/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 ~ppc x86"
  15 IUSE="alsa gnome lash nls xml"
  16
  17 RDEPEND="x11-libs/gtk+:2
  18         >=media-libs/ladspa-sdk-1.12
  19         media-sound/jack-audio-connection-kit
  20         alsa? ( media-libs/alsa-lib )
  21         lash? ( >=media-sound/lash-0.5 )
  22         gnome? ( >=gnome-base/libgnomeui-2 )
  23         nls? ( virtual/libintl )
  24         xml? ( dev-libs/libxml2
  25                 media-libs/liblrdf )"
  26 DEPEND="${RDEPEND}
  27         virtual/pkgconfig
  28         nls? ( sys-devel/gettext )"
  29
  30 DOCS=( AUTHORS BUGS ChangeLog NEWS README THANKS TODO WISHLIST )
  31
  32 src_prepare() {
  33         epatch \
  34                 "${FILESDIR}"/${PN}-1.4.5-asneeded.patch \
  35                 "${FILESDIR}"/${PN}-1.4.6-noalsa.patch \
  36                 "${FILESDIR}"/${PN}-1.4.7-disable_deprecated.patch
  37
  38         eautoreconf
  39 }
  40
  41 src_configure() {
  42         # Use lrdf.pc to get -I/usr/include/raptor2 (lrdf.h -> raptor.h)
  43         use xml && append-cppflags $($(tc-getPKG_CONFIG) --cflags lrdf)
  44
  45         econf \
  46                 $(use_enable alsa aseq) \
  47                 $(use_enable gnome) \
  48                 $(use_enable lash) \
  49                 $(use_enable nls) \
  50                 $(use_enable xml) \
  51                 $(use_enable xml lrdf)
  52 }