media-sound/hydrogen/hydrogen-1.0.0_beta1_pre20180301-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 COMMIT=1a477ffe380f153c5d9fb3495d9874df7f75334f
   7 inherit cmake-utils vcs-snapshot xdg-utils
   8
   9 DESCRIPTION="Advanced drum machine"
  10 HOMEPAGE="http://www.hydrogen-music.org/"
  11 SRC_URI="https://github.com/${PN}-music/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
  12
  13 LICENSE="GPL-2 ZLIB"
  14 SLOT="0"
  15 KEYWORDS="amd64 ppc ppc64 x86"
  16 IUSE="alsa +archive jack ladspa lash osc oss portaudio portmidi pulseaudio"
  17
  18 REQUIRED_USE="lash? ( alsa )"
  19
  20 RDEPEND="
  21         dev-qt/qtcore:5
  22         dev-qt/qtgui:5
  23         dev-qt/qtnetwork:5
  24         dev-qt/qtwidgets:5
  25         dev-qt/qtxml:5
  26         dev-qt/qtxmlpatterns:5
  27         >=media-libs/libsndfile-1.0.18
  28         alsa? ( media-libs/alsa-lib )
  29         archive? ( app-arch/libarchive )
  30         !archive? ( >=dev-libs/libtar-1.2.11-r3 )
  31         jack? ( virtual/jack )
  32         ladspa? ( media-libs/liblrdf )
  33         lash? ( media-sound/lash )
  34         osc? ( media-libs/liblo )
  35         portaudio? ( media-libs/portaudio )
  36         portmidi? ( media-libs/portmidi )
  37         pulseaudio? ( media-sound/pulseaudio )
  38 "
  39 DEPEND="${RDEPEND}
  40         virtual/pkgconfig
  41 "
  42
  43 DOCS=( AUTHORS ChangeLog DEVELOPERS README.txt )
  44
  45 PATCHES=( "${FILESDIR}/${P}-gnuinstalldirs.patch" )
  46
  47 src_configure() {
  48         local mycmakeargs=(
  49                 -DWANT_ALSA=$(usex alsa)
  50                 -DWANT_CPPUNIT=OFF
  51                 -DWANT_DEBUG=OFF
  52                 -DWANT_JACK=$(usex jack)
  53                 -DWANT_JACKSESSION=$(usex jack)
  54                 -DWANT_LADSPA=$(usex ladspa)
  55                 -DWANT_LASH=$(usex lash)
  56                 -DWANT_LIBARCHIVE=$(usex archive)
  57                 -DWANT_LRDF=$(usex ladspa)
  58                 -DWANT_OSC=$(usex osc)
  59                 -DWANT_OSS=$(usex oss)
  60                 -DWANT_PORTAUDIO=$(usex portaudio)
  61                 -DWANT_PORTMIDI=$(usex portmidi)
  62                 -DWANT_PULSEAUDIO=$(usex pulseaudio)
  63                 -DWANT_RUBBERBAND=OFF
  64         )
  65
  66         cmake-utils_src_configure
  67 }
  68
  69 src_install() {
  70         cmake-utils_src_install
  71         dosym ../../${PN}/data/doc /usr/share/doc/${PF}/html
  72 }
  73
  74 pkg_postinst() {
  75         xdg_mimeinfo_database_update
  76         xdg_desktop_database_update
  77 }
  78
  79 pkg_postrm() {
  80         xdg_mimeinfo_database_update
  81         xdg_desktop_database_update
  82 }