media-sound/horgand/horgand-1.14-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit desktop toolchain-funcs
   7
   8 DESCRIPTION="Opensource software organ"
   9 HOMEPAGE="http://horgand.berlios.de"
  10 #SRC_URI="mirror://berlios/${PN}/${P}.tar.gz"
  11 SRC_URI="mirror://gentoo/${P}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="amd64 ~ppc sparc x86"
  16 IUSE=""
  17
  18 RDEPEND="x11-libs/fltk:1
  19         x11-libs/libXpm
  20         media-libs/libsndfile
  21         media-libs/alsa-lib
  22         media-sound/alsa-utils
  23         media-sound/jack-audio-connection-kit"
  24 DEPEND="${RDEPEND}
  25         virtual/pkgconfig"
  26
  27 src_prepare() {
  28         default
  29         eapply "${FILESDIR}"/${P}-overflow.patch
  30 }
  31
  32 src_compile() {
  33         emake CXX="$(tc-getCXX)" CXXFLAGS="${CXXFLAGS} $(fltk-config --cxxflags) \
  34                 $(pkg-config --cflags jack) $(pkg-config --cflags sndfile)"
  35 }
  36
  37 src_install() {
  38         default
  39         doman man/${PN}.1
  40         newicon src/${PN}128.xpm ${PN}.xpm
  41         make_desktop_entry ${PN} Horgand ${PN}
  42 }