media-sound/herrie/herrie-2.2-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eutils toolchain-funcs
   7
   8 DESCRIPTION="Herrie is a command line music player"
   9 HOMEPAGE="http://herrie.info/"
  10 SRC_URI="http://herrie.info/distfiles/${P}.tar.bz2"
  11
  12 LICENSE="BSD-2 GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 ppc x86"
  15 IUSE="ao +alsa pulseaudio oss http modplug mp3 sndfile vorbis xspf unicode nls"
  16 REQUIRED_USE="|| ( ao alsa pulseaudio oss )"
  17
  18 RDEPEND="sys-libs/ncurses:0=[unicode?]
  19         >=dev-libs/glib-2:2
  20         ao? ( media-libs/libao )
  21         alsa? ( media-libs/alsa-lib )
  22         http? ( net-misc/curl )
  23         modplug? ( media-libs/libmodplug )
  24         mp3? ( media-libs/libmad
  25                 media-libs/libid3tag )
  26         pulseaudio? ( media-sound/pulseaudio )
  27         sndfile? ( media-libs/libsndfile )
  28         vorbis? ( media-libs/libvorbis )
  29         xspf? ( >=media-libs/libxspf-1.2 )"
  30 DEPEND="${RDEPEND}
  31         nls? ( sys-devel/gettext )
  32         virtual/pkgconfig"
  33
  34 PATCHES=(
  35         "${FILESDIR}/${PN}-chost_issue.patch"
  36         "${FILESDIR}/${P}-libxspf.patch"
  37         "${FILESDIR}/${P}-fix-buildsystem.patch"
  38 )
  39
  40 src_configure() {
  41         local EXTRA_CONF="verbose no_strip"
  42         use ao && EXTRA_CONF="${EXTRA_CONF} ao"
  43         use alsa && EXTRA_CONF="${EXTRA_CONF} alsa"
  44         use http || EXTRA_CONF="${EXTRA_CONF} no_http no_scrobbler"
  45         use mp3 || EXTRA_CONF="${EXTRA_CONF} no_mp3"
  46         use modplug || EXTRA_CONF="${EXTRA_CONF} no_modplug"
  47         use nls || EXTRA_CONF="${EXTRA_CONF} no_nls"
  48         use oss && EXTRA_CONF="${EXTRA_CONF} oss"
  49         use pulseaudio && EXTRA_CONF="${EXTRA_CONF} pulse"
  50         use sndfile || EXTRA_CONF="${EXTRA_CONF} no_sndfile"
  51         use unicode || EXTRA_CONF="${EXTRA_CONF} ncurses"
  52         use vorbis || EXTRA_CONF="${EXTRA_CONF} no_vorbis"
  53         use xspf || EXTRA_CONF="${EXTRA_CONF} no_xspf"
  54
  55         einfo "./configure ${EXTRA_CONF}"
  56         CC="$(tc-getCC)" PREFIX=/usr MANDIR=/usr/share/man \
  57                 ./configure ${EXTRA_CONF} || die "configure failed"
  58 }