media-sound/helm/helm-0.9.0-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit desktop xdg
   7
   8 DESCRIPTION="Open source polyphonic software synthesizer with lots of modulation"
   9 HOMEPAGE="https://tytel.org/helm/"
  10 SRC_URI="https://github.com/mtytel/helm/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="GPL-3+"
  13 SLOT="0"
  14 KEYWORDS="amd64"
  15 IUSE=""
  16
  17 DEPEND="
  18         media-libs/alsa-lib
  19         media-libs/freetype
  20         media-libs/lv2
  21         virtual/jack
  22         virtual/opengl
  23         x11-libs/libX11
  24         x11-libs/libXcursor
  25         x11-libs/libXext
  26         x11-libs/libXinerama
  27         x11-libs/libXrandr"
  28 RDEPEND="${DEPEND}
  29         !app-admin/helm
  30 "
  31
  32 DOCS=( changelog README.md )
  33
  34 PATCHES=(
  35         "${FILESDIR}/${P}-nomancompress.patch"
  36         "${FILESDIR}/${P}-fix-gcc91.patch"
  37 )
  38
  39 src_prepare() {
  40         default
  41         sed -e "s|/usr/lib/|/usr/$(get_libdir)/|" -i Makefile || die "Failed to fix libdir"
  42         sed -e "s|^\(CHANGES.*\)/|\1-${PVR}|" -i Makefile || die "Failed to fix doc path"
  43 }
  44
  45 src_compile() {
  46         emake PREFIX=/usr all
  47 }
  48
  49 src_install() {
  50         default
  51         make_desktop_entry /usr/bin/helm Helm /usr/share/helm/icons/helm_icon_32_1x.png
  52 }