media-sound/guitarix/guitarix-9999.ebuild

   1 # Copyright 2019-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python3_{6,7,8} )
   6 PYTHON_REQ_USE='threads(+)'
   7
   8 inherit python-any-r1 waf-utils xdg git-r3
   9
  10 MY_P="${PN}2-${PV}"
  11
  12 DESCRIPTION="Virtual guitar amplifier for Linux"
  13 HOMEPAGE="http://guitarix.org/"
  14 EGIT_REPO_URI="https://git.code.sf.net/p/guitarix/git"
  15
  16 LICENSE="GPL-2"
  17 SLOT="0"
  18 KEYWORDS=""
  19 IUSE="bluetooth debug lv2 nls +standalone zeroconf"
  20 REQUIRED_USE="|| ( lv2 standalone )"
  21
  22 COMMON_DEPEND="dev-cpp/eigen:3
  23         dev-cpp/glibmm:2
  24         dev-cpp/gtkmm:2.4
  25         dev-lang/sassc
  26         dev-libs/glib:2
  27         >=media-libs/libsndfile-1.0.17
  28         >=media-libs/zita-convolver-3:=
  29         media-libs/zita-resampler
  30         >=net-misc/curl-7.26.0
  31         >=sci-libs/fftw-3.1.2:3.0=
  32         x11-libs/gtk+:2
  33         lv2? ( media-libs/lv2 )
  34         standalone? (
  35                 dev-libs/boost:=
  36                 media-libs/liblrdf
  37                 media-libs/lilv
  38                 virtual/jack
  39                 bluetooth? ( net-wireless/bluez )
  40                 zeroconf? ( net-dns/avahi )
  41         )
  42 "
  43 # clearlooks gtk engine and roboto fonts are required for correct ui rendering
  44 RDEPEND="${COMMON_DEPEND}
  45         x11-themes/gtk-engines
  46         standalone? (
  47                 media-fonts/roboto
  48         )
  49 "
  50 DEPEND="${COMMON_DEPEND}
  51         ${PYTHON_DEPS}
  52         virtual/pkgconfig
  53         nls? ( dev-util/intltool )
  54 "
  55
  56 S="${WORKDIR}/${P}/trunk"
  57
  58 DOCS=( changelog README )
  59
  60 src_configure() {
  61         local myconf=(
  62                 --cxxflags-debug=""
  63                 --cxxflags-release="-DNDEBUG"
  64                 --ldflags="${LDFLAGS}"
  65                 --enable-lfs
  66                 --lib-dev
  67                 --no-desktop-update
  68                 --no-faust
  69                 --no-ldconfig
  70                 --shared-lib
  71                 $(use_enable nls)
  72                 $(usex bluetooth "" "--no-bluez")
  73                 $(usex debug "--debug" "")
  74                 $(usex lv2 "--lv2dir=${EPREFIX}/usr/$(get_libdir)/lv2" "--no-lv2 --no-lv2-gui")
  75                 $(usex standalone "" "--no-standalone")
  76                 $(usex zeroconf "" "--no-avahi")
  77         )
  78         waf-utils_src_configure "${myconf[@]}"
  79 }