media-sound/grip/grip-3.5.1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit eutils flag-o-matic toolchain-funcs libtool
   6
   7 DESCRIPTION="GTK+ based Audio CD Player/Ripper"
   8 HOMEPAGE="https://sourceforge.net/projects/grip/"
   9 SRC_URI="mirror://sourceforge/grip/${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
  14 IUSE="vorbis"
  15
  16 # lame and vorbis-tools are no real RDEPENDs. But without them
  17 # grip cannot convert ripped files to any format. So use them as
  18 # a sane default.
  19 RDEPEND="
  20         gnome-base/libgnome
  21         >=gnome-base/libgnomeui-2.2.0
  22         >=media-libs/id3lib-3.8.3
  23         media-sound/cdparanoia
  24         media-sound/lame
  25         net-misc/curl
  26         >=x11-libs/gtk+-2.2:2
  27         x11-libs/libX11
  28         x11-libs/pango
  29         x11-libs/vte:0
  30         vorbis? ( media-sound/vorbis-tools )
  31 "
  32 # gnome-extra/yelp, see bug 416843
  33 DEPEND="
  34         ${RDEPEND}
  35         sys-devel/gettext
  36         virtual/pkgconfig
  37 "
  38
  39 src_prepare() {
  40         default
  41
  42         sed '/^Icon/s@grip\b@gripicon@' -i grip.desktop || die
  43 }
  44
  45 src_configure() {
  46         # Bug #69536
  47         [[ $(tc-arch) == "x86" ]] && append-flags "-mno-sse"
  48
  49         strip-linguas be bg ca de en en_CA en_GB en_US es fi fr hu it ja nb nl pl_PL pt_BR ru sr vi zh_CN zh_HK zh_TW
  50
  51         econf
  52 }