media-sound/gnome-music/gnome-music-3.30.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python3_{4,5,6} )
   6
   7 inherit gnome.org gnome2-utils meson python-single-r1 xdg
   8
   9 DESCRIPTION="Music management for Gnome"
  10 HOMEPAGE="https://wiki.gnome.org/Apps/Music"
  11
  12 LICENSE="GPL-2+"
  13 SLOT="0"
  14 IUSE=""
  15 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  16
  17 KEYWORDS="~amd64 ~x86"
  18
  19 # At 3.30.2 libdazzle only used from .ui file, thus introspection not needed
  20 COMMON_DEPEND="${PYTHON_DEPS}
  21         net-libs/gnome-online-accounts[introspection]
  22         >=dev-libs/gobject-introspection-1.54:=
  23         >=x11-libs/gtk+-3.19.3:3[introspection]
  24         >=dev-libs/libdazzle-3.28.0
  25         >=media-libs/libmediaart-1.9.1:2.0[introspection]
  26         net-libs/libsoup:2.4[introspection]
  27         >=app-misc/tracker-1.99.1:=[introspection(+)]
  28         >=dev-python/pygobject-3.29.1:3[cairo,${PYTHON_USEDEP}]
  29         >=dev-python/pycairo-1.14.0[${PYTHON_USEDEP}]
  30         >=media-libs/grilo-0.3.4:0.3[introspection]
  31         >=media-plugins/grilo-plugins-0.3.8:0.3
  32 "
  33 # xdg-user-dirs-update needs to be there to create needed dirs
  34 # https://bugzilla.gnome.org/show_bug.cgi?id=731613
  35 RDEPEND="${COMMON_DEPEND}
  36         || (
  37                 >=app-misc/tracker-miners-1.99.1[gstreamer]
  38                 >=app-misc/tracker-miners-1.99.1[ffmpeg]
  39         )
  40         x11-libs/libnotify[introspection]
  41         media-libs/gstreamer:1.0[introspection]
  42         media-libs/gst-plugins-base:1.0[introspection]
  43         media-plugins/gst-plugins-meta:1.0
  44         media-plugins/grilo-plugins:0.3[tracker]
  45         x11-misc/xdg-user-dirs
  46 "
  47 DEPEND="${COMMON_DEPEND}
  48         dev-libs/libxml2:2
  49         dev-util/itstool
  50         >=sys-devel/gettext-0.19.8
  51         virtual/pkgconfig
  52 "
  53
  54 pkg_setup() {
  55         python_setup
  56 }
  57
  58 src_prepare() {
  59         sed -e '/sys.path.insert/d' -i "${S}"/gnome-music.in || die "python fixup sed failed"
  60         xdg_src_prepare
  61 }
  62
  63 src_install() {
  64         meson_src_install
  65         python_fix_shebang "${D}"usr/bin/gnome-music
  66         python_optimize
  67 }
  68
  69 pkg_postinst() {
  70         xdg_pkg_postinst
  71         gnome2_schemas_update
  72 }
  73
  74 pkg_postrm() {
  75         xdg_pkg_postrm
  76         gnome2_schemas_update
  77 }