media-sound/gbsplay/gbsplay-0.0.91-r2.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PLOCALES="de en"
   7 inherit l10n toolchain-funcs
   8
   9 DESCRIPTION="Nintendo Gameboy sound player for GBS format"
  10 HOMEPAGE="https://www.cgarbs.de/gbsplay.en.html"
  11 SRC_URI="mirror://gentoo/${P}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="+alsa nas nls oss"
  17
  18 RDEPEND="alsa? ( media-libs/alsa-lib:0 )
  19         nas? ( media-libs/nas:0 )"
  20
  21 DEPEND="${RDEPEND}
  22         nls? ( sys-devel/gettext:0 )"
  23
  24 PATCHES=(
  25         "${FILESDIR}/${P}-fix-buildsystem.patch"
  26 )
  27
  28 src_configure() {
  29         tc-export AR CC
  30
  31         # No econf, because "unknown option '--build=x86_64-pc-linux-gnu'"
  32         ./configure \
  33                 --prefix=/usr \
  34                 --mandir=/usr/share/man \
  35                 --docdir=/usr/share/doc/${PF} \
  36                 --without-xmmsplugin \
  37                 --without-test \
  38                 $(use_enable nls i18n) \
  39                 $(use_enable oss devdsp) \
  40                 $(use_enable alsa) \
  41                 $(use_enable nas) || die "Configure failed."
  42 }
  43
  44 src_compile() {
  45         emake CC="$(tc-getCC)" SPLINT="true"
  46 }
  47
  48 remove_disabled_locale() {
  49         rm -r "${D}"/usr/share/locale/$1 || die
  50 }
  51
  52 src_install() {
  53         default
  54
  55         l10n_for_each_disabled_locale_do remove_disabled_locale
  56 }