media-sound/entagged-tageditor/entagged-tageditor-0.35.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit desktop java-pkg-2 java-ant-2
   7
   8 DESCRIPTION="Open-source audiofile tagger"
   9 HOMEPAGE="http://entagged.sourceforge.net/"
  10 SRC_URI="mirror://gentoo/${P}.tar.gz"
  11
  12 LICENSE="GPL-2+ LGPL-2.1+"
  13 SLOT="0"
  14 KEYWORDS="~amd64"
  15 IUSE=""
  16
  17 S="${WORKDIR}"
  18
  19 RDEPEND=">=virtual/jre-1.5
  20         dev-java/squareness-jlf:0
  21         dev-db/hsqldb:0"
  22
  23 DEPEND=">=virtual/jdk-1.5
  24         dev-db/hsqldb:0"
  25
  26 EANT_BUILD_XML="entagged/build.xml"
  27 EANT_BUILD_TARGET="build"
  28
  29 src_prepare() {
  30         java-pkg-2_src_prepare
  31         mkdir -p test/entagged/junit || die
  32         mv entagged/entagged/junit test/entagged || die
  33         rm entagged/*.jar || die
  34         java-pkg_jarfrom hsqldb hsqldb.jar entagged/hsqldb.jar
  35         cd entagged || die
  36         eapply "${FILESDIR}"/${P}-buildfixes.patch
  37 }
  38
  39 src_install() {
  40         cd entagged || die
  41         java-pkg_newjar ${P}.jar ${PN}.jar
  42         java-pkg_register-dependency squareness-jlf
  43         java-pkg_dolauncher ${PN} --main entagged.tageditor.TagEditorFrameSplash
  44         newicon entagged/tageditor/resources/icons/entagged-icon.png ${PN}.png
  45         make_desktop_entry ${PN} "Entagged Tag Editor" ${PN}
  46 }